sh
شنبه 11 آبان 1387, 22:14 عصر
برای راه حل میتونی به لینکهای زیر نگاه کنی :
VB 2005 "converting images into binary (http://www.dreamincode.net/forums/showtopic51183.htm)
StoringImagesInVB (http://www.vbdotnetheaven.com/UploadFile/aghiondea2/StoringImagesInVB11122005034248AM/StoringImagesInVB.aspx?ArticleID=7ed1fe42-0819-4912-88ae-bbc43829d8a6)
یا کد :
' Add a reference to System.Configuration.dll to the project.
Imports System
Imports System.IO
Imports System.Drawing
Imports System.Data.SqlClient
Imports System.Configuration
Imports System.Drawing.Imaging
Public Class SqlServerImages
''' <summary>
''' Load an image from a file, and create a byte array using the image format type
''' (i.e. Bmp, Png, Jpeg, etc.)
''' </summary>
''' <param name="fileName">Full path file name for the image file.</param>
''' <param name="format">The image type (Bmp, Jpeg, Png, etc.)</param>
''' <returns>A byte array representing the image.</returns>
Public Function LoadImage(ByVal fileName As String, ByVal format As ImageFormat) As Byte()
Dim img As Image = Image.FromFile(fileName)
Using ms As New MemoryStream()
img.Save(ms, format)
Return ms.ToArray()
End Using
End Function
''' <summary>
''' Save the image byte array to the Image column in the SQL Server table, with ID and Name.
''' </summary>
''' <param name="id">The identity information for the image</param>
''' <param name="name">The human readable name for the image</param>
''' <param name="image">The byte array representing the image</param>
''' <returns>Number of rows affected</returns>
Public Function SaveImage(ByVal id As Integer, ByVal name As String, ByVal image As Byte()) As Integer
Dim connectionString As String = ConfigurationManager.ConnectionStrings("Connection").ConnectionString
Using connection As New SqlConnection(connectionString)
connection.Open()
Dim commandText As String = "INSERT INTO tblImgData(ID, Name, Picture) VALUES (@ID, @Name, @Picture)"
Using command As New SqlCommand(commandText, connection)
command.Parameters.AddWithValue("@ID", id)
command.Parameters.AddWithValue("@Name", name)
command.Parameters.AddWithValue("@Picture", image)
Return command.ExecuteNonQuery()
End Using
End Using
End Function
''' <summary>
''' Pull the image from the database with the given ID. Translate the byte array
''' into a image, and return an instance of an Image class.
''' </summary>
''' <param name="id">The identity information for the image.</param>
''' <returns>An Image instance</returns>
Public Function RetrieveImage(ByVal id As Integer) As Image
Dim connectionString As String = ConfigurationManager.ConnectionStrings("Connection").ConnectionString
Using connection As New SqlConnection(connectionString)
connection.Open()
Dim commandText As String = "SELECT Picture FROM tblImgData WHERE ID = @ID"
Using command As New SqlCommand(commandText, connection)
command.Parameters.AddWithValue("@ID", id)
Dim buffer As Byte() = command.ExecuteScalar()
Using ms As New MemoryStream(buffer)
Return Image.FromStream(ms)
End Using
End Using
End Using
End Function
End Class