سلام
برای جلوگیری از ساخت تاپیکهای جدید که بعضاً تکراری هستند تصمیم گرفتم این تاپیک رو بسازم و نمونه کدهای کاربردی زبان ASP رو در آن قرار دهم تا با اینکار هم تاپیک جامعی برای این موضوع داشته باشیم و هم از ارسال تاپیکهای جدید کمی جلوگیری کرده باشیم. لذا در زیر نمونه کدهای انتخابی رو قرار دادم و امیدوارم به مرور کاملتر شود (البته به کمک شما دوستان).
چند نکته و تقاضا:
1. دوستانی که کد جالب و بدرد بخوری دارند ( هرچند ساده ) به همین شکلی که در زیر آمده است ( عنوان٬ مورد استفاده ٬ فایل‌های مورد نیاز ٬ توضیحات٬ نمونه کد + ترکیب رنگی استفاده شده و خطوط بین هر موضوع ) کد مربوطه را در همین تاپیک ارسال کنند .
2. درصورتی که کد معرفی شده از سایتی برداشت شده لطفاً لینک سایت مربوطه را در ادامه پست‌تان قرار دهید .
3. دوستان لطف کنند از ارسال پیام‌های خارج از بحث خودداری کنند که با عرض شرمندگی در اسرع وقت پست مربوطه حذف خواهد شد .
4. نظرات خود را برای هرچه بهتر شدن این تاپیک برای من PM کنید .
موفق و پیروز باشید
تاریخ هجری شمسی
فایل‌های مورد نیاز : Shamsi.asp
توضیحات : تا اونجایی که یادمه مشکل سال کبیسش حل شده
نمونه کد :
<%
FMonArray= array (0,31,31,31,31,31,31,30,30,30,30,30,30)
EMonArray= Array(0,31, 28,31,30,31,30,31,31,30,31,30,31)
W = Array ("یک‌شنبه", "دوشنبه", "سه‌شنبه", "چهار‌شنبه", "پنج‌شنبه", "جمعه", "شنبه")
Mon = Array ("فروردین", "اردیبهشت", "خرداد", "تیر", "مرداد", "شهریور", "مهر", "آبان", "آذر", "دی", "بهمن", "اسفند")
EYear= Year(Date)
EMon= Month(Date)
EDay = Day(Date)
ELeap=0
if ((EYear mod 4))= 0 Then
ELeap =1
End if
Cnt=EMon-1
Temp=0
While Cnt<>0
if ((Cnt=2)and(ELeap=1)) Then
Temp= Temp+29
else
Temp= Temp + EMonArray(Cnt)
end if
Cnt=Cnt-1
Wend
EDayOfYear= Temp+EDay
' Convert to Farsi
Temp= EDayOfYear-79
if Temp>0 Then
FYear= EYear-621
else
FYear= EYear-622
if ((FYear mod 4)=3) then
Temp= Temp+366
else
Temp= Temp+365
End if
End if
if (FYear mod 4)=3 Then
FLeap=1
else
Fleap=0
End if
Cnt= 1
While( (Temp<>0) and (Temp>FMonArray(Cnt)) )
if Cnt=12 Then
if (FLeap=1) Then
Temp=Temp-30
else Temp= Temp-29
end if
else Temp= Temp-FMonArray(Cnt)
end if
Cnt= Cnt+1
Wend
if Temp<>0 Then
FMon = Cnt
FDay= Temp
else
FMon= 12
FDay=30
End if
DateShamsi = W(WeekDay(Date) - 1) & " " & FDay& " " & Mon(FMon - 1) & " " &FYear
%>
<%
response.write(DateShamsi)
%>
برداشت شده : فکر کنم یکی از پستهای آقای مهدوی
نمایش تصادفی یک خط از فایل
مورد استفاده : نمایش Tip های مختلف در صفحه
فایل‌های مورد نیاز : text.txt, rndline.asp
توضیحات :
1. در این مثال فایل text.txt می‌بایست شامل 20 خط باشد .
2. پوشه‌ی ذخیره‌ی این فایل باید اجازه ( permission ) لازم را برای اعمال تغییرات داشته باشد .
کد نمونه :
<%
Randomize
' Number of 1-line entries in the text file. 21 here
RandNo = Int(Rnd*20)
' Now open the file with the 20 entries
userFile = "text.txt"
userFile=Server.Mappath (userFile)
Set fs = CreateObject("Scripting.FileSystemObject")
Set thisfile = fs.OpenTextFile(userFile, 1, False)
' If you wish to skip lines, enter that number here
For i = 1 to RandNo -1
thisfile.SkipLine()
Next
' Now assign the variable RandomLineItem to the line selected
RandomLineItem = thisfile.ReadLine
Set fs = Nothing
' Display the Random Line
Response.write RandomLineItem
%>
محل برداشت : http://www.wondersky.com
روز شمار
فایل‌های مورد نیاز : countdown.asp
کد نمونه :
<%
dim strDateTime
strDateTime = CDate("2/9/2000")
strFutureDay = #12/31#
Response.write "There are" & INT(strFutureDay - strDateTime) & " more days till December 31st."
%>
محل برداشت : http://www.wondersky.com
بدست آوردن IP Address کاربر
مورد استفاده : ثبت آی پی و استفاده از آن برای جلوگیری از ثبت بیش از یک رأی در نظرخواهی
فایل‌های مورد نیاز : ip.asp
نمونه کد :
My IP address is <%=Request.ServerVariables("REMOTE_ADDR")%>محل برداشت : http://www.wondersky.com
بدست آوردن نام فایلها
مورد استفاده : به هنگامی که نیاز داشته باشید نام فایل‌های موجود در یک پوشه را بدانید .
فایل‌های مورد نیاز : filename.asp
توضیحات :
برای استفاده از نمونه کد زیر می‌بایست پوشه‌ای با نام MyFolder در پوشه‌ی جاری ایجاد نمایید .
نمونه کد:
<%
Set MyDirectory=Server.CreateObject("Scripting.FileSys temObject")
Set MyFiles=MyDirectory.GetFolder(Server.MapPath("MyFo lder"))
For each filefound in MyFiles.files
Response.write filefound.Name
response.write "<br>"
Next
%>
محل برداشت : http://www.wondersky.com
ساخت پوشه
فایل‌های مورد نیاز : CreateDir.asp
توضیحات :
پوشه‌ی ذخیره‌ی این فایل باید اجازه ( permission ) لازم را برای اعمال تغییرات داشته باشد .
نمونه کد :
<%
set fs=createobject("scripting.filesystemobject")
MyFolder=server.mappath("/personal/data/")
If NOT fs.folderexists(MyFolder) then
fs.createfolder(MyFolder)
End If
' Check if the creation was a success or not
If fs.folderexists(MyFolder) then
Response.write "Success"
Else
Response.write "Failure."
End If
%>
محل برداشت : http://www.wondersky.com
حذف پوشه
فایل‌های مورد نیاز : RemoveDir.asp
توضیحات :
پوشه‌ی ذخیره‌ی این فایل باید اجازه ( permission ) لازم را برای اعمال تغییرات داشته باشد .
نمونه کد :
<%
set fs=createobject("scripting.filesystemobject")
MyFolder=server.mappath("/download/incoming/")
set delDir = fs.getfolder(myFolder)
delDir.delete
set delDir = Nothing
'Check if the deletion was a success or Not
If fs.folderexists(myFolder) then
Response.write "Deleted"
Else
Response.write "Error"
End If
%>
محل برداشت : http://www.wondersky.com
استفاده از کامپوننت CDONT
مورد استفاده : جهت ارسال ایمیل به دیگران
فایل‌های مورد نیاز : CDONT1.asp , CDONT2.asp , CDONT3.asp , CDONT.dll
توضیحات :
1. در زیر سه نوع کد برای استفاده از این کامپوننت آمده است :
کد اول : ارسال یک ایمیل ساده
کد دوم : ارسال ایمیل به شکل HTML
کد سوم : ارسال ایمیل به شکل HTML + ضمیمه
2. برای استفاده از کدهای زیر می‌بایست کامپوننت یاد شده ( CDONT.dll ) در سیستم شما رجیستر شده باشد . درصورتی که این کامپوننت را در اختیار ندارید در گوگل جستجو کنید .
نمونه کد :
کد اول :
<%
Dim MyBody
Dim MyCDONTSMail
Set MyCDONTSMail = CreateObject("CDONTS.NewMail")
MyCDONTSMail.From = "somebody@nowhere.com"
MyCDONTSMail.To = "nobody@nowhere.com"
MyCDONTSMail.Subject = "This is a Test"
MyBody = "Thank you " & vbCrLf
MyBody = MyBody & "Please do visit us again" & vbCrLf
MyBody = MyBody & "Always at your service"
MyCDONTSMail.Body = MyBody
MyCDONTSMail.Send
set MyCDONTSMail = nothing
%>
کد دوم :
<%
Dim MyCDONTSMail
Dim HTML
Set MyCDONTSMail = CreateObject("CDONTS.NewMail")
HTML = "<!DOCTYPE HTML PUBLIC""-//IETF//DTD HTML//EN"">"
HTML = HTML & "<html>"
HTML = HTML & "<head>"
HTML = HTML & "<title>Sending CDONTS Email Using HTML</title>"
HTML = HTML & "</head>"
HTML = HTML & "<body bgcolor=""FFFFFF"">"
HTML = HTML & "<font size =""3"" face=""Arial"">"
HTML = HTML & "Name Of Store<br>"
HTML = HTML & "Incoming Customer Order<br>"
HTML = HTML & "<p align = ""center"">Bla Bla Bla Bla Bla</p>"
HTML = HTML & "<body>"
HTML = HTML & "<html>"
MyCDONTSMail.From= "myself@myplace.com"
MyCDONTSMail.To="toyou@urplace.com"
MyCDONTSMail.Subject="Saying Hello"
MyCDONTSMail.BodyFormat=0
MyCDONTSMail.MailFormat=0
MyCDONTSMail.Body=HTML
MyCDONTSMail.Send
set MyCDONTSMail=nothing
%>
کد سوم :
<%
Dim MyBody
Dim MyCDONTSMail
Set MyCDONTSMail = CreateObject("CDONTS.NewMail")
MyCDONTSMail.From= "somebody@nowhere.com"
MyCDONTSMail.To= "nobody@nowhere.com"
MyCDONTSMail.Cc="nobody2@nowhere.com"
MyCDONTSMail.Subject="This is a Test"
MyCDONTSMail.AttachFile Server.MapPath("/somedirectory/myfile.txt")
' or you could specify the path exactly if you knew it like below
' MyCDONTSMail.AttachFile "C:\inetpub\wwwroot\somedirectory\myfile.txt"
MyBody = "Thank you" & vbCrLf
MyBody = MyBody & "Please visit us again" & vbCrLf
MyBody = MyBody & "Always at your service"
MyCDONTSMail.Body= MyBody
MyCDONTSMail.Send
set MyCDONTSMail=nothing
%>
محل برداشت : http://www.wondersky.com
هش با MD5
مورد استفاده : هش ( Hash ) نمودن عبارات جهت بالا بردن امنیت . این کد کاربردهای مختلفی دارد .
فایل‌های مورد نیاز : MD5.asp
نمونه کد :
<%
' Derived from the RSA Data Security, Inc. MD5 Message-Digest Algorithm,
' as set out in the memo RFC1321.
'
'
' ASP VBScript code for generating an MD5 'digest' or 'signature' of a string. The
' MD5 algorithm is one of the industry standard methods for generating digital
' signatures. It is generically known as a digest, digital signature, one-way
' encryption, hash or checksum algorithm. A common use for MD5 is for password
' encryption as it is one-way in nature, that does not mean that your passwords
' are not free from a dictionary attack.
'
' This is 'free' software with the following restrictions:
'
' You may not redistribute this code as a 'sample' or 'demo'. However, you are free
' to use the source code in your own code, but you may not claim that you created
' the sample code. It is expressly forbidden to sell or profit from this source code
' other than by the knowledge gained or the enhanced value added by your own code.
'
' Use of this software is also done so at your own risk. The code is supplied as
' is without warranty or guarantee of any kind.
'
' Should you wish to commission some derivative work based on this code provided
' here, or any consultancy work, please do not hesitate to contact us.
'
' Web Site: http://www.frez.co.uk
' E-mail: sales@frez.co.uk
Private Const BITS_TO_A_BYTE = 8
Private Const BYTES_TO_A_WORD = 4
Private Const BITS_TO_A_WORD = 32
Private m_lOnBits(30)
Private m_l2Power(30)
m_lOnBits(0) = CLng(1)
m_lOnBits(1) = CLng(3)
m_lOnBits(2) = CLng(7)
m_lOnBits(3) = CLng(15)
m_lOnBits(4) = CLng(31)
m_lOnBits(5) = CLng(63)
m_lOnBits(6) = CLng(127)
m_lOnBits(7) = CLng(255)
m_lOnBits(8) = CLng(511)
m_lOnBits(9) = CLng(1023)
m_lOnBits(10) = CLng(2047)
m_lOnBits(11) = CLng(4095)
m_lOnBits(12) = CLng(8191)
m_lOnBits(13) = CLng(16383)
m_lOnBits(14) = CLng(32767)
m_lOnBits(15) = CLng(65535)
m_lOnBits(16) = CLng(131071)
m_lOnBits(17) = CLng(262143)
m_lOnBits(18) = CLng(524287)
m_lOnBits(19) = CLng(1048575)
m_lOnBits(20) = CLng(2097151)
m_lOnBits(21) = CLng(4194303)
m_lOnBits(22) = CLng(8388607)
m_lOnBits(23) = CLng(16777215)
m_lOnBits(24) = CLng(33554431)
m_lOnBits(25) = CLng(67108863)
m_lOnBits(26) = CLng(134217727)
m_lOnBits(27) = CLng(268435455)
m_lOnBits(28) = CLng(536870911)
m_lOnBits(29) = CLng(1073741823)
m_lOnBits(30) = CLng(2147483647)
m_l2Power(0) = CLng(1)
m_l2Power(1) = CLng(2)
m_l2Power(2) = CLng(4)
m_l2Power(3) = CLng(8)
m_l2Power(4) = CLng(16)
m_l2Power(5) = CLng(32)
m_l2Power(6) = CLng(64)
m_l2Power(7) = CLng(128)
m_l2Power(8) = CLng(256)
m_l2Power(9) = CLng(512)
m_l2Power(10) = CLng(1024)
m_l2Power(11) = CLng(2048)
m_l2Power(12) = CLng(4096)
m_l2Power(13) = CLng(8192)
m_l2Power(14) = CLng(16384)
m_l2Power(15) = CLng(32768)
m_l2Power(16) = CLng(65536)
m_l2Power(17) = CLng(131072)
m_l2Power(18) = CLng(262144)
m_l2Power(19) = CLng(524288)
m_l2Power(20) = CLng(1048576)
m_l2Power(21) = CLng(2097152)
m_l2Power(22) = CLng(4194304)
m_l2Power(23) = CLng(8388608)
m_l2Power(24) = CLng(16777216)
m_l2Power(25) = CLng(33554432)
m_l2Power(26) = CLng(67108864)
m_l2Power(27) = CLng(134217728)
m_l2Power(28) = CLng(268435456)
m_l2Power(29) = CLng(536870912)
m_l2Power(30) = CLng(1073741824)
Private Function LShift(lValue, iShiftBits)
If iShiftBits = 0 Then
LShift = lValue
Exit Function
ElseIf iShiftBits = 31 Then
If lValue And 1 Then
LShift = &H80000000
Else
LShift = 0
End If
Exit Function
ElseIf iShiftBits < 0 Or iShiftBits > 31 Then
Err.Raise 6
End If
If (lValue And m_l2Power(31 - iShiftBits)) Then
LShift = ((lValue And m_lOnBits(31 - (iShiftBits + 1))) * m_l2Power(iShiftBits)) Or &H80000000
Else
LShift = ((lValue And m_lOnBits(31 - iShiftBits)) * m_l2Power(iShiftBits))
End If
End Function
Private Function RShift(lValue, iShiftBits)
If iShiftBits = 0 Then
RShift = lValue
Exit Function
ElseIf iShiftBits = 31 Then
If lValue And &H80000000 Then
RShift = 1
Else
RShift = 0
End If
Exit Function
ElseIf iShiftBits < 0 Or iShiftBits > 31 Then
Err.Raise 6
End If
RShift = (lValue And &H7FFFFFFE) \ m_l2Power(iShiftBits)
If (lValue And &H80000000) Then
RShift = (RShift Or (&H40000000 \ m_l2Power(iShiftBits - 1)))
End If
End Function
Private Function RotateLeft(lValue, iShiftBits)
RotateLeft = LShift(lValue, iShiftBits) Or RShift(lValue, (32 - iShiftBits))
End Function
Private Function AddUnsigned(lX, lY)
Dim lX4
Dim lY4
Dim lX8
Dim lY8
Dim lResult
lX8 = lX And &H80000000
lY8 = lY And &H80000000
lX4 = lX And &H40000000
lY4 = lY And &H40000000
lResult = (lX And &H3FFFFFFF) + (lY And &H3FFFFFFF)
If lX4 And lY4 Then
lResult = lResult Xor &H80000000 Xor lX8 Xor lY8
ElseIf lX4 Or lY4 Then
If lResult And &H40000000 Then
lResult = lResult Xor &HC0000000 Xor lX8 Xor lY8
Else
lResult = lResult Xor &H40000000 Xor lX8 Xor lY8
End If
Else
lResult = lResult Xor lX8 Xor lY8
End If
AddUnsigned = lResult
End Function
Private Function F(x, y, z)
F = (x And y) Or ((Not x) And z)
End Function
Private Function G(x, y, z)
G = (x And z) Or (y And (Not z))
End Function
Private Function H(x, y, z)
H = (x Xor y Xor z)
End Function
Private Function I(x, y, z)
I = (y Xor (x Or (Not z)))
End Function
Private Sub FF(a, b, c, d, x, s, ac)
a = AddUnsigned(a, AddUnsigned(AddUnsigned(F(b, c, d), x), ac))
a = RotateLeft(a, s)
a = AddUnsigned(a, b)
End Sub
Private Sub GG(a, b, c, d, x, s, ac)
a = AddUnsigned(a, AddUnsigned(AddUnsigned(G(b, c, d), x), ac))
a = RotateLeft(a, s)
a = AddUnsigned(a, b)
End Sub
Private Sub HH(a, b, c, d, x, s, ac)
a = AddUnsigned(a, AddUnsigned(AddUnsigned(H(b, c, d), x), ac))
a = RotateLeft(a, s)
a = AddUnsigned(a, b)
End Sub
Private Sub II(a, b, c, d, x, s, ac)
a = AddUnsigned(a, AddUnsigned(AddUnsigned(I(b, c, d), x), ac))
a = RotateLeft(a, s)
a = AddUnsigned(a, b)
End Sub
Private Function ConvertToWordArray(sMessage)
Dim lMessageLength
Dim lNumberOfWords
Dim lWordArray()
Dim lBytePosition
Dim lByteCount
Dim lWordCount
Const MODULUS_BITS = 512
Const CONGRUENT_BITS = 448
lMessageLength = Len(sMessage)
lNumberOfWords = (((lMessageLength + ((MODULUS_BITS - CONGRUENT_BITS) \ BITS_TO_A_BYTE)) \ (MODULUS_BITS \ BITS_TO_A_BYTE)) + 1) * (MODULUS_BITS \ BITS_TO_A_WORD)
ReDim lWordArray(lNumberOfWords - 1)
lBytePosition = 0
lByteCount = 0
Do Until lByteCount >= lMessageLength
lWordCount = lByteCount \ BYTES_TO_A_WORD
lBytePosition = (lByteCount Mod BYTES_TO_A_WORD) * BITS_TO_A_BYTE
lWordArray(lWordCount) = lWordArray(lWordCount) Or LShift(Asc(Mid(sMessage, lByteCount + 1, 1)), lBytePosition)
lByteCount = lByteCount + 1
Loop
lWordCount = lByteCount \ BYTES_TO_A_WORD
lBytePosition = (lByteCount Mod BYTES_TO_A_WORD) * BITS_TO_A_BYTE
lWordArray(lWordCount) = lWordArray(lWordCount) Or LShift(&H80, lBytePosition)
lWordArray(lNumberOfWords - 2) = LShift(lMessageLength, 3)
lWordArray(lNumberOfWords - 1) = RShift(lMessageLength, 29)
ConvertToWordArray = lWordArray
End Function
Private Function WordToHex(lValue)
Dim lByte
Dim lCount
For lCount = 0 To 3
lByte = RShift(lValue, lCount * BITS_TO_A_BYTE) And m_lOnBits(BITS_TO_A_BYTE - 1)
WordToHex = WordToHex & Right("0" & Hex(lByte), 2)
Next
End Function
Public Function MD5(sMessage)
Dim x
Dim k
Dim AA
Dim BB
Dim CC
Dim DD
Dim a
Dim b
Dim c
Dim d
Const S11 = 7
Const S12 = 12
Const S13 = 17
Const S14 = 22
Const S21 = 5
Const S22 = 9
Const S23 = 14
Const S24 = 20
Const S31 = 4
Const S32 = 11
Const S33 = 16
Const S34 = 23
Const S41 = 6
Const S42 = 10
Const S43 = 15
Const S44 = 21
x = ConvertToWordArray(sMessage)
a = &H67452301
b = &HEFCDAB89
c = &H98BADCFE
d = &H10325476
For k = 0 To UBound(x) Step 16
AA = a
BB = b
CC = c
DD = d
FF a, b, c, d, x(k + 0), S11, &HD76AA478
FF d, a, b, c, x(k + 1), S12, &HE8C7B756
FF c, d, a, b, x(k + 2), S13, &H242070DB
FF b, c, d, a, x(k + 3), S14, &HC1BDCEEE
FF a, b, c, d, x(k + 4), S11, &HF57C0FAF
FF d, a, b, c, x(k + 5), S12, &H4787C62A
FF c, d, a, b, x(k + 6), S13, &HA8304613
FF b, c, d, a, x(k + 7), S14, &HFD469501
FF a, b, c, d, x(k + 8), S11, &H698098D8
FF d, a, b, c, x(k + 9), S12, &H8B44F7AF
FF c, d, a, b, x(k + 10), S13, &HFFFF5BB1
FF b, c, d, a, x(k + 11), S14, &H895CD7BE
FF a, b, c, d, x(k + 12), S11, &H6B901122
FF d, a, b, c, x(k + 13), S12, &HFD987193
FF c, d, a, b, x(k + 14), S13, &HA679438E
FF b, c, d, a, x(k + 15), S14, &H49B40821
GG a, b, c, d, x(k + 1), S21, &HF61E2562
GG d, a, b, c, x(k + 6), S22, &HC040B340
GG c, d, a, b, x(k + 11), S23, &H265E5A51
GG b, c, d, a, x(k + 0), S24, &HE9B6C7AA
GG a, b, c, d, x(k + 5), S21, &HD62F105D
GG d, a, b, c, x(k + 10), S22, &H2441453
GG c, d, a, b, x(k + 15), S23, &HD8A1E681
GG b, c, d, a, x(k + 4), S24, &HE7D3FBC8
GG a, b, c, d, x(k + 9), S21, &H21E1CDE6
GG d, a, b, c, x(k + 14), S22, &HC33707D6
GG c, d, a, b, x(k + 3), S23, &HF4D50D87
GG b, c, d, a, x(k + 8), S24, &H455A14ED
GG a, b, c, d, x(k + 13), S21, &HA9E3E905
GG d, a, b, c, x(k + 2), S22, &HFCEFA3F8
GG c, d, a, b, x(k + 7), S23, &H676F02D9
GG b, c, d, a, x(k + 12), S24, &H8D2A4C8A
HH a, b, c, d, x(k + 5), S31, &HFFFA3942
HH d, a, b, c, x(k + 8), S32, &H8771F681
HH c, d, a, b, x(k + 11), S33, &H6D9D6122
HH b, c, d, a, x(k + 14), S34, &HFDE5380C
HH a, b, c, d, x(k + 1), S31, &HA4BEEA44
HH d, a, b, c, x(k + 4), S32, &H4BDECFA9
HH c, d, a, b, x(k + 7), S33, &HF6BB4B60
HH b, c, d, a, x(k + 10), S34, &HBEBFBC70
HH a, b, c, d, x(k + 13), S31, &H289B7EC6
HH d, a, b, c, x(k + 0), S32, &HEAA127FA
HH c, d, a, b, x(k + 3), S33, &HD4EF3085
HH b, c, d, a, x(k + 6), S34, &H4881D05
HH a, b, c, d, x(k + 9), S31, &HD9D4D039
HH d, a, b, c, x(k + 12), S32, &HE6DB99E5
HH c, d, a, b, x(k + 15), S33, &H1FA27CF8
HH b, c, d, a, x(k + 2), S34, &HC4AC5665
II a, b, c, d, x(k + 0), S41, &HF4292244
II d, a, b, c, x(k + 7), S42, &H432AFF97
II c, d, a, b, x(k + 14), S43, &HAB9423A7
II b, c, d, a, x(k + 5), S44, &HFC93A039
II a, b, c, d, x(k + 12), S41, &H655B59C3
II d, a, b, c, x(k + 3), S42, &H8F0CCC92
II c, d, a, b, x(k + 10), S43, &HFFEFF47D
II b, c, d, a, x(k + 1), S44, &H85845DD1
II a, b, c, d, x(k + 8), S41, &H6FA87E4F
II d, a, b, c, x(k + 15), S42, &HFE2CE6E0
II c, d, a, b, x(k + 6), S43, &HA3014314
II b, c, d, a, x(k + 13), S44, &H4E0811A1
II a, b, c, d, x(k + 4), S41, &HF7537E82
II d, a, b, c, x(k + 11), S42, &HBD3AF235
II c, d, a, b, x(k + 2), S43, &H2AD7D2BB
II b, c, d, a, x(k + 9), S44, &HEB86D391
a = AddUnsigned(a, AA)
b = AddUnsigned(b, BB)
c = AddUnsigned(c, CC)
d = AddUnsigned(d, DD)
Next
MD5 = LCase(WordToHex(a) & WordToHex(b) & WordToHex(c) & WordToHex(d))
End Function
%>
<%response.write md5(YourString)%>
محل برداشت : http://www.frez.co.uk
شمارنده‌ی دفعات مشاهده‌ی یک صفحه
مورد استفاده : ذخیره‌ی آمار مشاهده‌ی یک صفحه
فایل‌های مورد نیاز : counter.asp , asp_count.txt
توضیحات :
پوشه‌ی ذخیره‌ی این فایل باید اجازه ( permission ) لازم را برای اعمال تغییرات داشته باشد .
نمونه کد :
<%
on error resume next
' Create a server object
set fso = createobject("scripting.filesystemobject")
' Target the text file to be opened
set act = fso.opentextfile(server.mappath("asp_count.txt"))
' Read the value of the text document
' If the text document does not exist then the on error resume next
' will drop down to the next line
counter = clng(act.readline)
' Add one to the counter
counter = counter + 1
' Close the object
act.close
' Create a new text file on the server
Set act = fso.CreateTextFile(server.mappath("asp_count.txt") , true)
' Write the current counter value to the text document
act.WriteLine(counter)
' Close the object
act.Close
' Write the counter to the browser as text
Response.Write counter
%>
محل برداشت : http://www.CodeAve.com
شمارنده‌ی تعداد جلسات استفاده از سایت
مورد استفاده : ذخیره‌ی آمار مشاهده‌ی سایت
فایل‌های مورد نیاز : session_counter.asp , session_count.txt
توضیحات :
پوشه‌ی ذخیره‌ی این فایل باید اجازه ( permission ) لازم را برای اعمال تغییرات داشته باشد .
نمونه کد :
<%
set fso = createobject("scripting.filesystemobject")
set act = fso.opentextfile(server.mappath("session_count.txt "))
counter = clng(act.readline)
if session("been_here_before") = "" then
session("been_here_before") = "Yes"
counter = counter + 1
' act.close
Set act = fso.CreateTextFile(server.mappath("session_count.t xt"), true)
act.WriteLine(counter)
end if
act.Close
Response.Write counter
%>
محل برداشت : http://www.CodeAve.com
شمارنده‌ی تعداد دفعات مراجعه به یک صفحه در روز
مورد استفاده : ذخیره‌ی آمار مشاهده‌ی روزانه‌ی یک صفحه
فایل‌های مورد نیاز : dailyhits.asp
توضیحات :
پوشه‌ی ذخیره‌ی این فایل باید اجازه ( permission ) لازم را برای اعمال تغییرات داشته باشد .
نمونه کد :
<%
on error resume next
' Create a server object
set fso = createobject("scripting.filesystemobject")
' Target the text file to be read.
' The text file is continually updated with the current date from the server
set act = fso.opentextfile(server.mappath("daily_count-"& month(date()) & day(date()) & year(date())&".txt"))
' Read the value contained in the current day hit counter
' If there is no file for the current day the on error resume next command above
' will force the program to the next line
counter = clng(act.readline)
' Add one to the counter. If there was no value the counter will be set to a value of one
counter = counter + 1
' Close the text object.
act.close
' Create a new text file on the server with the current date as part of the name
Set act = fso.createtextfile(server.mappath("daily_count-"& month(date()) & day(date()) & year(date())&".txt"), true)
' Write the counter value to the text object
act.writeline(counter)
' Close the text object
act.Close
%>
<%= counter %> Total Hits for <%= date() %>
محل برداشت : http://www.CodeAve.com
پاسخ با نقل قول
