نمایشگر قیمت

[hoshy345]

با سلام خدمت همه دوستان و اساتید محترم
در اکثر برنامهای خرید و فروش برای اینکه مشتری بتونه مبلغی رو که باید پرداخت کنه رو ببینه از وچیزی به نام #poly desplay# یا نمایشگر (اگه درست نوشته باشم) استفاده میکنن اگه بخواهیم از این نمایشگر در برنامه ای که با اکسس نوشته شده استفاده کنیم باید چکاری را انجام داد و از چه کدی استفاده کرد
منتظر راهنمایی شما بزرگواران
ممنون

[davood-ahmadi]

خوب مشخصه. یک فرم درست کن و در آن فرم مبلغ را نشان بده .
البته مسائل دیگری وجود دارد که در چه محلی و شرایط آن محل و نمایشگر شما چه باشد؟
توضیحات شما کافی نیست. لطفاً بیشتر توضیح بدهید.

[hoshy345]

دوست عزیز pole desply رو شاید در اکثر هایپرمارکتها دیده باشید یک صفحه دیجیتالی که به com port کامپیوتر وصل میشه تا مشتری بتونه مبلغی رو که باید پرداخت کنه ببینه
ممنون از شما دوست خوب

[davood-ahmadi]

من تا حالا با pole desply کار نکردم ولی باید حداقل یک نرم افزار و یا یک درایور نصب داشته باشد و یک رابط که بتوان از طریق آن با دستگاه مورد نظر ارتباط برقرار کرد. آیا نرم افزار خاصی دارد و آیا آن رابط می شناسید؟

[hoshy345]

سلام دوست عزیز
این pole Desply هم از طریق پورت usb و هم com به کامپیوتر وصل میشه و درایور هم داره ولی چطور باید در برنامه خرید وفروش اون رو تعریف کرد رو نمیدونم
و یک سوال دیگه
اگه بخواهیم از یک تکس باکس برای رمز استفاده کنیم input mask= password قرار میدهیم حال اگه با کد Dim pass As String

pass = InputBox("Entere your password", "password")
If pass = "1450" Then
چطوریinput mask این رو به شکل پاسورد در اورد
ممنون

[davood-ahmadi]

InputBox این خاصیت را ندارد.

شما می توانید از جایی که این محصول را خریدید با قسمت پشتیبانی و یا فروش تماس گرفته و با آنها این مسئله را در میان بگذارید که می خواهید با زبان VB با سخت افزار مربوطه ارتباط برقرار کنید. باید آنها یک و یا چندین فایل Dll را به شما معرفی کنند که احتمالاً آن در درایور نصب شده موجود می باشد.
و یا اینکه اگر سخت افزار فایل Help و یا کاتالوگ داشت می توانید در آن جستجو کنید

[hoshy345]

اگه من بخام واسه حذف رکوردی از فرم پاسورد بزارم باید چکار کنم

[davood-ahmadi]

جای حذف در فرم به شما بستگی داره. حالا می تونه در یک فرم پسوود باشه یا در فرم دیگر.
در مورد حذف جستجو کن مطلب زیاد پیدا می کنی.

[amirzazadeh]

اگه من بخام واسه حذف رکوردی از فرم پاسورد بزارم باید چکار کنم
این کد رو تو رویداد on delete فرمت اضافه کن(پسورد عدد 10 انتخاب شده شما میتونین عوضش کنین)

Private Sub Form_Delete(Cancel As Integer)
If InputBox("enter pass") = 10 Then
cancle = False
Else
Cancel = True
MsgBox "This record can't be deleted."
End If
End Sub

[hoshy345]

دوست عزیز من میخام کدی که کاربر وارد میکنه بصورت پاسورد یعنی ستاره نشان داده بشه در غیر این صورت این پاسورد چه ارزشی داره
ایا راهی هست که در input box نوشتها بصورت ستاره نشان داده شود
ممنون

[amirzazadeh]

دوست عزیز من میخام کدی که کاربر وارد میکنه بصورت پاسورد یعنی ستاره نشان داده بشه در غیر این صورت این پاسورد چه ارزشی داره
ایا راهی هست که در input box نوشتها بصورت ستاره نشان داده شود
ممنون
در این صورت شما باید در هنگام حذف داده ها به جای inputbox یک فرم با تکست باک ماسک دار رو فراخوانی کنین

[hoshy345]

اگه بخام تکست باکس رو تو همون فرم بزارم کار راحتیه ولی در تمام فرمها باید اون تکست باکس رو بزارم ولی ولی چطورمیتونم یک فرم برای این کار بزارم که در تمام فرمها اون روcall کنم

[amirzazadeh]

اگه بخام تکست باکس رو تو همون فرم بزارم کار راحتیه ولی در تمام فرمها باید اون تکست باکس رو بزارم ولی ولی چطورمیتونم یک فرم برای این کار بزارم که در تمام فرمها اون روcall کنم
یه روش بهتر: input box با خاصیت ماسک
این کد رو توی یک ماژول ذخیره کن یک input box جدید با نام input boxDk ایجاد میکنه که همون خاصیت مورد نظر رو داره

Option Compare Database

Option Explicit
'////////////////////////////////////////////////////////////////////
'Password masked inputbox
'Allows you to hide characters entered in a VBA Inputbox.
'
'Code written by Daniel Klann
'March 2003
'////////////////////////////////////////////////////////////////////


'API functions to be used
Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _
ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long

Private Declare Function GetModuleHandle Lib "kernel32" Alias "GetModuleHandleA" (ByVal lpModuleName As String) As Long

Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" _
(ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, _
ByVal dwThreadId As Long) As Long

Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long

Private Declare Function SendDlgItemMessage Lib "user32" Alias "SendDlgItemMessageA" _
(ByVal hDlg As Long, ByVal nIDDlgItem As Long, ByVal wMsg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long

Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, _
ByVal lpClassName As String, _
ByVal nMaxCount As Long) As Long

Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long

'Constants to be used in our API functions
Private Const EM_SETPASSWORDCHAR = &HCC
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
Private Const HC_ACTION = 0

Private hHook As Long

Public Function NewProc(ByVal lngCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Dim RetVal
Dim strClassName As String, lngBuffer As Long

If lngCode < HC_ACTION Then
NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam)
Exit Function
End If

strClassName = String$(256, " ")
lngBuffer = 255

If lngCode = HCBT_ACTIVATE Then 'A window has been activated

RetVal = GetClassName(wParam, strClassName, lngBuffer)

If Left$(strClassName, RetVal) = "#32770" Then 'Class name of the Inputbox

'This changes the edit control so that it display the password character *.
'You can change the Asc("*") as you please.
SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0
End If

End If

'This line will ensure that any other hooks that may be in place are
'called correctly.
CallNextHookEx hHook, lngCode, wParam, lParam

End Function

Public Function InputBoxDK(Prompt, Optional Title, Optional Default, Optional XPos, _
Optional YPos, Optional HelpFile, Optional Context) As String
Dim lngModHwnd As Long, lngThreadID As Long

lngThreadID = GetCurrentThreadId
lngModHwnd = GetModuleHandle(vbNullString)

hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID)

InputBoxDK = InputBox(Prompt, Title, Default, XPos, YPos, HelpFile, Context)
UnhookWindowsHookEx hHook

End Function

[hoshy345]

امیرزازاده عزیز من نتونستم از کد شما استفاده کنم اگه براتون زحمتی نیست بر من منت نهاده و یک فایل نمونه برام بگذارید
با تشکر

[amirzazadeh]

امیرزازاده عزیز من نتونستم از کد شما استفاده کنم اگه براتون زحمتی نیست بر من منت نهاده و یک فایل نمونه برام بگذارید
با تشکر
یک نمونه براتون آماده کردم پسورد برای حذف رکورد عدد10انتخاب شده.

[hoshy345]

دوست عزیز از لطف شما بینهایت ممنونم همیشه پیروز و موفق باشید