اجرای برنامه ای و انتظار تا بسته شدن آن

[hasanain]

سؤال اول - چگونه میتوان برنامه ای را از درون محیط vb اجرا کرد و تا زمان بسته شدن آن منتظر ماند؟

سؤال دوم - تفاوت دستور shell با WinExec چیست؟

من سورس برنامه ای را دیدم که از طریق رجیستری به برنامه های نصب شده دست می یافت و اگر بخواهیم Uninstall هم میکند، در اجرای دستور uninstall از WinExec که یک تابع Api است استفاده کرده است.

در واقع آنچه که من از دوستان تقاضا دارم این است که بتوانم با همین دستور api برنامه uninstallـــی را اجرا و تا پایان یافتن آن صبر کنم. نزدیک به یک ساعت و 10 دقیقه است که مشغول جستجو در سایت هستم و نتوانستم پیدا کنم، پیشاپیش اگر سؤالم تکراری است، عذرخواهم.

[hasanain]

این جواب را از MSDN پیدا کردم که با استفاده از Shell عمل کرده است:

Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type

Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessID As Long
dwThreadID As Long
End Type

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
hHandle As Long, ByVal dwMilliseconds As Long) As Long

Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
lpApplicationName As String, ByVal lpCommandLine As String, ByVal _
lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As String, _
lpStartupInfo As STARTUPINFO, lpProcessInformation As _
PROCESS_INFORMATION) As Long

Private Declare Function CloseHandle Lib "kernel32" _
(ByVal hObject As Long) As Long

Private Declare Function GetExitCodeProcess Lib "kernel32" _
(ByVal hProcess As Long, lpExitCode As Long) As Long

Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const INFINITE = -1&

Public Function ExecCmd(cmdline$)
Dim proc As PROCESS_INFORMATION
Dim start As STARTUPINFO

' Initialize the STARTUPINFO structure:
start.cb = Len(start)

' Start the shelled application:
ret& = CreateProcessA(vbNullString, cmdline$, 0&, 0&, 1&, _
NORMAL_PRIORITY_CLASS, 0&, vbNullString, start, proc)

' Wait for the shelled application to finish:
ret& = WaitForSingleObject(proc.hProcess, INFINITE)
Call GetExitCodeProcess(proc.hProcess, ret&)
Call CloseHandle(proc.hThread)
Call CloseHandle(proc.hProcess)
ExecCmd = ret&
End Function

Sub Form_Click()
Dim retval As Long
retval = ExecCmd("notepad.exe")
MsgBox "Process Finished, Exit Code " & retval
End Sub

[xxxxx_xxxxx]

تاپيك:
http://www.barnamenevis.org/forum/showthread.php?t=117941
پست:
http://www.barnamenevis.org/forum/showpost.php?p=576106&postcount=8