فرستادن دستور به برنامه Run در منو Start

[sadegi]

با عرض سلام خدمت دوستان عزیز
چطور میتونم به برنامه Run موجود در منو Start دستوری بفرستم و بعد هم از طریق اون
اجراش کنم
:flower: :flower: :flower:

[MM_Mofidi]

از ShellExecute استفاده کن .
اینم یک مثال
به جای mailto:vbcode@vbcode.com از دستور مورد نظرت استفاده کن این برای
ارسال میل مورد استفاده قرار میگیره
:موفق: :موفق:
Declarations


Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
Private Const SW_SHOW = 5

Code


ShellExecute hwnd, "open", "mailto:vbcode@vbcode.com", vbNullString, vbNullString, SW_SHOW

[Morteza Manafpour]

نیازی به استفاده از توابع خارجی نیست.
همین Shell هم کافیه ::نوشتن::

[sadegi]

دوست عزیز ممنون
:flower: :flower: :flower:

[Taha_u]

نیازی به استفاده از توابع خارجی نیست.
همین Shell هم کافیه
shell رو فقط در مورد (*.exe) میشه استفاده کرد!!!

[delphi77]

و اگر فایل مورد نظر shar Network Places بود چی و همین دستور شما هم مشکل داره

************ Code Start **********
' This code was originally written by Dev Ashish.
' It is not to be altered or distributed,
' except as part of an application.
' You are free to use it in any application,
' provided the copyright notice is left unchanged.
'
' Code Courtesy of
' Dev Ashish
'
Private Declare Function apiShellExecute Lib "shell32.dll" _
Alias "ShellExecuteA" _
(ByVal hwnd As Long, _
ByVal lpOperation As String, _
ByVal lpFile As String, _
ByVal lpParameters As String, _
ByVal lpDirectory As String, _
ByVal nShowCmd As Long) _
As Long

'***App Window Constants***
Public Const WIN_NORMAL = 1 'Open Normal
Public Const WIN_MAX = 3 'Open Maximized
Public Const WIN_MIN = 2 'Open Minimized

'***Error Codes***
Private Const ERROR_SUCCESS = 32&
Private Const ERROR_NO_ASSOC = 31&
Private Const ERROR_OUT_OF_MEM = 0&
Private Const ERROR_FILE_NOT_FOUND = 2&
Private Const ERROR_PATH_NOT_FOUND = 3&
Private Const ERROR_BAD_FORMAT = 11&

'***************Usage Examples***********************
'Open a folder: ?fHandleFile("C:\TEMP\",WIN_NORMAL)
'Call Email app: ?fHandleFile("mailto:dash10@hotmail.com",WIN_NORMAL)
'Open URL: ?fHandleFile("http://home.att.net/~dashish", WIN_NORMAL)
'Handle Unknown extensions (call Open With Dialog):
' ?fHandleFile("C:\TEMP\TestThis",Win_Normal)
'Start Access instance:
' ?fHandleFile("I:\mdbs\CodeNStuff.mdb", Win_NORMAL)
'************************************************* ***

Function fHandleFile(stFile As String, lShowHow As Long)
Dim lRet As Long, varTaskID As Variant
Dim stRet As String
'First try ShellExecute
lRet = apiShellExecute(hWndAccessApp, vbNullString, _
stFile, vbNullString, vbNullString, lShowHow)

If lRet > ERROR_SUCCESS Then
stRet = vbNullString
lRet = -1
Else
Select Case lRet
Case ERROR_NO_ASSOC:
'Try the OpenWith dialog
varTaskID = Shell("rundll32.exe shell32.dll,OpenAs_RunDLL " _
& stFile, WIN_NORMAL)
lRet = (varTaskID <> 0)
Case ERROR_OUT_OF_MEM:
stRet = "Error: Out of Memory/Resources. Couldn't Execute!"
Case ERROR_FILE_NOT_FOUND:
stRet = "Error: File not found. Couldn't Execute!"
Case ERROR_PATH_NOT_FOUND:
stRet = "Error: Path not found. Couldn't Execute!"
Case ERROR_BAD_FORMAT:
stRet = "Error: Bad File Format. Couldn't Execute!"
Case Else:
End Select
End If
fHandleFile = lRet & _
IIf(stRet = "", vbNullString, ", " & stRet)
End Function
'************ Code End **********

[sadegi]

دوست عزیز اکه امکان داشته باشه یکم توضیح بدین
shar Network Places=؟؟؟
خیلی ممنون

[Hassan-Ahmadi]

دوست عزیز اگر می خوای که فقط فایل های اجرایی رو اجرا کنی Shell خود ویژوال خوبه ولی اگر میخوای چیزایی مثل :
باز کردن یک درایو و یا پوشه از طریق اکسپلورر
پروپرتی فایل ویا پوشه
باز کردن انواع فایل ها با برنامه پیشفرض ویندوز
باز کردن سایت از طریق نوشتن آدرس
و چند چیز دیگر که الان یادم نیست
از ShellExecute استفاده کن
ShellExecute از توابع Api ویندوز است

[sadegi]

دوست عزیز خیلی ممنون

[delphi77]

دوست عزیز اکه امکان داشته باشه یکم توضیح بدین
shar Network Places=؟؟؟
خیلی ممنون


کدی که براتون گذاشتم مشکل شما را به نحو احسن حل مس کنه
چه فایل بر روی شبکه باشه و با هر پسوندی که باشه حتی windows هم نشناسه باز هم فایل را براتون باز می کنه

البته من هم مانند شما به دنبال cammand های run هستم اگر کسی می داند بگوید که آنها را از کجا می توان یافت