ساعت آنالوگ ( توضیحات یک خط )

[knight-rak]

سلام
** میدونم قبلا تاپیک زده شده بحث شده منم اینارو از توی همونا پیدا کردم ولی هیچ کدومشون در مورد اینکه چرا باید این اعداد باشه توضیح نداده **
کد ساعت آنالوگ بوسیله خط رو چندین نوع مختلف دارم ولی همشون از یه تابع سینوس و کسینوس استفاده کردن با این فرق که بعضی از جاهاشون فرق میکنه ( مقدار دهی آرگومانها ) حالا من مشکلم اینه که این خط کدی که تو همین پست میزارم چطور کار میکنه و چطور عمل میکنه منظورم اینه که اون Y چرا باید 600 تا ازش کم بشه چرا باید عدد 66 تقسیم به 14 بشه و با ثانیه جمع بشه بعدش ضرب بشه با 44 تقسیم 420 بشه ؟؟؟؟؟ و همینطور مقادیر دقیقه چرا باید عوض بشه و ساعت ( این که خیلی از مقادیرش عوض شده )

X = Form1.Width / 2
Y = Form1.Height / 2.2

s = Second(Time())

Line (X, Y)-(X + (Y - 600) * Cos((66 / 14 + s * (44 / 420))), Y + (Y - 600) * Sin((66 / 14 + s * (44 / 420))))

Line (X, Y)-(X + (Y - 800) * Cos((66 / 14 + m * (44 / 420))), Y + (Y - 800) * Sin((66 / 14 + m * (44 / 420)))), vbYellow
Line (X, Y)-(X + (Y - 1200) * Cos(66 / 14 + h * (44 / 84) + (m / 12) * (44 / 420)), Y + (Y - 1200) * Sin(66 / 14 + h * (44 / 84) + (m / 12) * (44 / 420))), vbWhite

موفق باشید ....

[knight-rak]

دوستان یعنی هیچ کدوم شرحی برای این چند خط کد نتونستین پیدا کنید !!!!! جدا بهش نیاز دارم خیلی ضروری و فوری هستش ممنون میشم اگر کمک کنید


موفق باشید ....

[m.soleimani]

سلام
** میدونم قبلا تاپیک زده شده بحث شده منم اینارو از توی همونا پیدا کردم ولی هیچ کدومشون در مورد اینکه چرا باید این اعداد باشه توضیح نداده **
کد ساعت آنالوگ بوسیله خط رو چندین نوع مختلف دارم ولی همشون از یه تابع سینوس و کسینوس استفاده کردن با این فرق که بعضی از جاهاشون فرق میکنه ( مقدار دهی آرگومانها ) حالا من مشکلم اینه که این خط کدی که تو همین پست میزارم چطور کار میکنه و چطور عمل میکنه منظورم اینه که اون Y چرا باید 600 تا ازش کم بشه چرا باید عدد 66 تقسیم به 14 بشه و با ثانیه جمع بشه بعدش ضرب بشه با 44 تقسیم 420 بشه ؟؟؟؟؟ و همینطور مقادیر دقیقه چرا باید عوض بشه و ساعت ( این که خیلی از مقادیرش عوض شده )

X = Form1.Width / 2
Y = Form1.Height / 2.2

s = Second(Time())

Line (X, Y)-(X + (Y - 600) * Cos((66 / 14 + s * (44 / 420))), Y + (Y - 600) * Sin((66 / 14 + s * (44 / 420))))

Line (X, Y)-(X + (Y - 800) * Cos((66 / 14 + m * (44 / 420))), Y + (Y - 800) * Sin((66 / 14 + m * (44 / 420)))), vbYellow
Line (X, Y)-(X + (Y - 1200) * Cos(66 / 14 + h * (44 / 84) + (m / 12) * (44 / 420)), Y + (Y - 1200) * Sin(66 / 14 + h * (44 / 84) + (m / 12) * (44 / 420))), vbWhite

موفق باشید ....

همیشه برای این که بهتر متوجه بشی به قانون اولویت عملگرها دقت کن شما برای خودت بیا داخلی‌ترین پرانتزها را پیدا کن و به ترتیب بنویسشون بعد که از پیچیدگی موضوع کم شد بهتر متوجه منظور برنامه نویس خواهی شد البته درست دقت نکردم به کد خواستم راه حل بهت بدم ولی فکر کنم طرف قصدش بوده با توجه به اندازه‌های فرمش اندازه ساعت را تعین کنه این در واقع قسمتی از کد هست که ظاهر ساعت شما را می‌سازه نسبت به زمان سیستم هم تغییر می‌کنه موفق باشید./

[knight-rak]

ممنون که حد اقل یکی جواب داد " دوست عزیز میدونم که اول باید اولویت ها رو دید حتی اینم میدونم که باید از سینوس و کسینوس واسه ثابت نگه داشتن خط و چرخش استفاده کرد ولی سوال من اینه چرا از اون مقدار اعداد ثابت استفاده کرده

Cos((66 / 14 + s * (44 / 420)))

چرا باید 66 تقسیم به 14 بشه ؟؟؟؟؟؟؟ این واسه من سوال هست اگر میشه دوستان زودتر راهنمایی کنن خیلی بهش نیاز دارم
موفق باشید ....

[m.soleimani]

ممنون که حد اقل یکی جواب داد " دوست عزیز میدونم که اول باید اولویت ها رو دید حتی اینم میدونم که باید از سینوس و کسینوس واسه ثابت نگه داشتن خط و چرخش استفاده کرد ولی سوال من اینه چرا از اون مقدار اعداد ثابت استفاده کرده

Cos((66 / 14 + s * (44 / 420)))

چرا باید 66 تقسیم به 14 بشه ؟؟؟؟؟؟؟ این واسه من سوال هست اگر میشه دوستان زودتر راهنمایی کنن خیلی بهش نیاز دارم
موفق باشید ....

به احتمال زیاد یه سری تنظیمات شخصی برای زیباتر شدن نمایش ساعت در نظر گرفته « با توجه به این‌که کل کد رو ندیدم » در کل متوجه نکته حیاتی که برای ادامه کارت مشکل ساز بشه توی این قسمت از کد نمی‌بینم اگر نیاز داری بهتر راهنماییت کنم کل کد رو بزار موفق باشی./

[knight-rak]

اینم کل سورس فقط هیچ ربطی به زیبایی نداره چون برای ظاهر توی چند خط قبلش مقدار دهی شده اینا واسه حرکت عقربه هستش : ممنون میشم زودتر کمک کنید چون کارم بدجوری عجله ای هستش ( چرا از اون اعداد استفاده شده )

Private Sub Form_Load()
Me.BackColor = vbBlack
End Sub
Private Sub Timer1_Timer()

Form1.Refresh
X = Form1.Width / 2
Y = Form1.Height / 2.2
Circle (X, Y), Y - 200, vbWhite
Circle (X, Y), Y - 220, vbWhite
For i = 1 To 12
Circle (X + (Y - 400) * Cos(i * 22 / 42), Y + (Y - 400) * Sin(i * 22 / 42)), 50, vbRed
Next
h = Hour(Time())
If h > 12 Then
h = h - 12
End If
m = Minute(Time())
s = Second(Time())
Line (X, Y)-(X + (Y - 600) * Cos((66 / 14 + s * (44 / 420))), Y + (Y - 600) * Sin((66 / 14 + s * (44 / 420)))), vbBlue
Line (X, Y)-(X + (Y - 800) * Cos((66 / 14 + m * (44 / 420))), Y + (Y - 800) * Sin((66 / 14 + m * (44 / 420)))), vbYellow
Line (X, Y)-(X + (Y - 1200) * Cos(66 / 14 + h * (44 / 84) + (m / 12) * (44 / 420)), Y + (Y - 1200) * Sin(66 / 14 + h * (44 / 84) + (m / 12) * (44 / 420))), vbWhite
End Sub

موفق باشید ....

[m.soleimani]

اینی که گذاشتی فقط داره از ابعاد فرمش و یه سری فرمول ریاضی که منطقش زیاد روشن نیست استفاده می‌کنه تا حرکت عقربه‌های ساعت رو نشون بده من یه کد برات قرار می‌دم ببین به کارت میاد یا نه موفق باشی./




Option Explicit
Const T As Double = 57.29577951
Private Sub Form_Load()
Me.Height = 2048
Me.Width = 2048
End Sub
Private Sub Form_Resize()
Me.ScaleHeight = 100
Me.ScaleWidth = 100
End Sub
Private Sub Timer1_Timer()
Dim H As Long, M As Long, S As Long 'time units
Dim Hd As Double, Md As Double, Sd As Double 'Degrees
Dim Hr As Double, Mr As Double, Sr As Double 'Radians
Me.Cls
H = Hour(Time): M = Minute(Time): S = Second(Time)
If H >= 12 Then H = H - 12
Hd = H * 30
Hd = Hd + M / 2
Md = M * 6
Sd = S * 6
Hd = Hd - 90: Md = Md - 90: Sd = Sd - 90
If Hd < 0 Then Hd = Hd + 360
If Md < 0 Then Md = Md + 360
If Sd < 0 Then Sd = Sd + 360
Hr = Hd / T: Mr = Md / T: Sr = Sd / T
Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.5 * Cos(Hr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.5 * Sin(Hr))), vbBlack
Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.6 * Cos(Mr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.6 * Sin(Mr))), vbBlue
Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.7 * Cos(Sr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.7 * Sin(Sr))), vbRed
End Sub

[knight-rak]

خیلی ممنون از لطفت دوست عزیز این کدی که شما قرار دادین خیلی واضح تر هستش

فقط اگر امکانش هست این قسمت ها رو یکم شرح بدین که چرا باید این کارا بشه :

H = Hour(Time): M = Minute(Time): S = Second(Time)
If H >= 12 Then H = H - 12
Hd = H * 30
Hd = Hd + M / 2
Md = M * 6
Sd = S * 6
Hd = Hd - 90: Md = Md - 90: Sd = Sd - 90
If Hd < 0 Then Hd = Hd + 360
If Md < 0 Then Md = Md + 360
If Sd < 0 Then Sd = Sd + 360
Hr = Hd / T: Mr = Md / T: Sr = Sd / T

بعدش اینکه تو این سینوس و کسینوس ها یه سری ثابت ها مثل 50 و 0.5 وMe.ScaleHeight / 2 و این چیزا واسه چی هست و چطور کار میکنه خیلی ممنون میشم

Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.5 * Cos(Hr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.5 * Sin(Hr))), vbBlack
Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.6 * Cos(Mr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.6 * Sin(Mr))), vbBlue
Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.7 * Cos(Sr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.7 * Sin(Sr))), vbRed


موفق باشد ....

[knight-rak]

ببخشید این ثابت که تعریف کردید چی هست و عددش از کجا اومده ؟؟؟ (روش بدست اوردن عدد)

Const T As Double = 57.29577951

موفق باشید ....

[knight-rak]

اگر نخواییم وسط صفحه باشه چکار کنیم باید کدوم مقدار تغییر کنه تا یجای ثابت بمونه
موفق باشید ....

[m.soleimani]

ببخشید این ثابت که تعریف کردید چی هست و عددش از کجا اومده ؟؟؟ (روش بدست اوردن عدد)

Const T As Double = 57.29577951

موفق باشید ....

دوست عزیز رادیان واحد اندازه گيري زاويه هست
برای به دست آوردن درجه رادیان مورد نظر خودتون را با این عدد ضرب می‌کنید
برای مثال برای تبدیل 1.5 رادیان به درجه اون رو با عدد بالا ضرب می‌کنید که نتیجه می‌شه 85.94 درجه
و البته شما می‌تونید برای این که درجه مورد نظر خودتون را به دست بیارین رادیان مورد نظر خودتون را تقسیم کنید به 0.017453293 موفق باشید./

[m.soleimani]

خیلی ممنون از لطفت دوست عزیز این کدی که شما قرار دادین خیلی واضح تر هستش

فقط اگر امکانش هست این قسمت ها رو یکم شرح بدین که چرا باید این کارا بشه :

H = Hour(Time): M = Minute(Time): S = Second(Time)
If H >= 12 Then H = H - 12
Hd = H * 30
Hd = Hd + M / 2
Md = M * 6
Sd = S * 6
Hd = Hd - 90: Md = Md - 90: Sd = Sd - 90
If Hd < 0 Then Hd = Hd + 360
If Md < 0 Then Md = Md + 360
If Sd < 0 Then Sd = Sd + 360
Hr = Hd / T: Mr = Md / T: Sr = Sd / T

بعدش اینکه تو این سینوس و کسینوس ها یه سری ثابت ها مثل 50 و 0.5 وMe.ScaleHeight / 2 و این چیزا واسه چی هست و چطور کار میکنه خیلی ممنون میشم

Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.5 * Cos(Hr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.5 * Sin(Hr))), vbBlack
Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.6 * Cos(Mr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.6 * Sin(Mr))), vbBlue
Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.7 * Cos(Sr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.7 * Sin(Sr))), vbRed


موفق باشد ....

تعریف همش که کلی وقت می‌بره ولی در کل ScaleHeight يکي از متددهای فرم هست که ميزان تغيير اندازه طول فرم را برای شما مشخص می‌کنه این برای این هست که همیشه ساعت مورد نظر به یک شکل دیده بشه موفق باشید./

[knight-rak]

ممنون ولی میشه بگید چطور موقعیت ساعت رو عوض کنم و سایزش رو فیکس کنم که مثلا یه گوشه با سایز ثابت باشه

موفق باشید ....

[m.soleimani]

ممنون ولی میشه بگید چطور موقعیت ساعت رو عوض کنم و سایزش رو فیکس کنم که مثلا یه گوشه با سایز ثابت باشه

موفق باشید ....

توی پست قبلی به عنوان یه توضیح کلی براتون گفتم که متد ScaleHeight نسبت به تغییر اندازه فرم شما واکنش نشون می‌ده و ساعت را در صفحه شم همیشه به یک صورت نشون می‌ده برای این‌که با این مورد روبه رو نشین کافیه به جای استفاده از اون X , Y مورد نظر خودتون را به صورت اعداد ثابت بهش بدین تا توی فضایی که شما در نظر دارین نمایش داده بشه و با تغییر اندزه‌ها هم عکس‌العمل نشون نده موفق باشید./

[knight-rak]

با تغییر این مقدار کل ساعت بهم میریزه و قاطی میکنه
ممنون میشم اگر خودتون یه زحمتی بگشید موقعیتش رو با اندازه عقربه هاش رو دست کاری کنید و نمونه سورس قرار بدید
Line (50, 50)-(Me.ScaleHeight / 2 + ((Me.ScaleHeight / 2) * 0.5 * Cos(Hr)), Me.ScaleWidth / 2 + ((Me.ScaleHeight / 2) * 0.5 * Sin(Hr))), vbBlack
این مقدار واسه چی هستش وقتی تغییر میدم از قاطی هم قاطی تر میشه مگه نباید نقطه شروع باشه تو متد لاین که تا جایی که من خبر دارم نقطه شروع هست ولی این جا نمیدونم : Line (50, 50)

[knight-rak]

منتظرم دوست عزیز دیگه وقتی ندارم

موفق باشید ....

[m.soleimani]

این مقدار واسه چی هستش وقتی تغییر میدم از قاطی هم قاطی تر میشه مگه نباید نقطه شروع باشه تو متد لاین که تا جایی که من خبر دارم نقطه شروع هست ولی این جا نمیدونم : Line (50, 50)

این متد برای رسم خط و مستطیل استفاده می‌شه به این شکل Line(X1,Y1)-(X2,Y2) , Color , BF
که پرانتز اول مختصات نقطه شروع و پرانتز دوم مختصات نقطه مقصد است و بين اين دو نقطه يک خط رسم می‌کنه و Color هم که رنگش هست ، برای این که یه مستطیل تو خالی بکشه به تنهايي کلمه B رو آخرش وارد می‌کنی و برای این که یه مستطيل تو پر رو داشته باشی باید BF رو در آخرش وارد کنی موفق باشی./

[knight-rak]

دوست عزیز ممنون ولی من میدونم این متد چکار میکنه میخواستم بدونم توی این کد چه مقداری رو تغییر میده آخه کل ساعت رو خراب میکنه

حالا میشه ساعت رو یجا ثابت نگه داشت ؟؟؟؟ اگر آره میشه لطف کنید یه نمونه بدید

موفق باشید ....

[m.soleimani]

دوست عزیز ممنون ولی من میدونم این متد چکار میکنه میخواستم بدونم توی این کد چه مقداری رو تغییر میده آخه کل ساعت رو خراب میکنه

حالا میشه ساعت رو یجا ثابت نگه داشت ؟؟؟؟ اگر آره میشه لطف کنید یه نمونه بدید

موفق باشید ....

گفته بودی توضیحات یه خط حالا خودت قضاوت کن
اگر کدی نبود مشکل بعید نبود
اگر توضیحی خواستی بهش نرسیدی حق با شما
ولی احساس می‌کنم که قصد داری پروژت رو برات انجام بدم خودت با یکم سعی و خطا به دستش میاری متدها رو هم که خوب می‌شناسی پس نباید مشکل خاصی داشته باشی به هر حال امیدوارم که به نتیجه برسی تا جایی که حوصله یاری می‌کرد بهت کمک کردم موفق باشی./

[knight-rak]

سلام
دوست عزیز حرف شما درست ولی زمانی توضیحات یک خط بود که من سورس داده بودم شما هم گفتین این مقادیر معنی خاصی نداره بیایین از این سورس استفاده کنین حالا شما قضاوت کنین وقتی شما یه سورسی به من دادین و من ازتون در موردش توضیح میخوام این اشتباه هستش

موفق باشید ....

[vbhamed]

سلام

ببينيد
بايد اصول كار رو بدونيد تا ديگه اين اعداد براتون عجيب نباشه

اول از همه بايد صفحه رو طبق مختصات مثلثاتي در بياريد، در حالت معمول نقطه 0 و 0 گوشه سمت چپ بالاي فرم هست اما ما مي‌خواهيم نقطه 0 و 0 وسط فرم باشه، به بالا و راست مثبت و به پايين و چپ منفي بشه، ضمنا براي راحتي ما ساعت رو درون يك پيكچر باكس رسم مي كنيم نه فرم، اينطوري انتقال ساعت به جاي دلخواه روي فرم هم خيلي راحت و از درون محيط طراحي يا با كد نويسي قابل انجام هست

براي تصحيح مختصات، خاصيتهاي زير رو براي پيكچر باكس تنظيم مي كنيم



AutoRedraw = True
ScaleLeft = -50
ScaleWidth = 100
ScaleTop = 50
ScaleHeight = -100


67517

طبق شكل بالا فرض كنيد خط آبي رنگ عقربه ثانيه شمار ساعت هست كه 10 ثانيه رو نشون مي ده
براي رسم اين عقربه بايد از مركز دايره يعني نقطه O خطي تا نقطه A رسم كنيد
مختصات مركز دايره يعني مركز ساعت كه اختياريه و دست خودتونه كه ما 0, 0 گرفتيم، اما بايد مختصات نقطه A رو بدست بياريد

به صورت خيلي ساده مختصات نقطه A ميشه

A(r * sin(x), r * Cos(x))


Private Sub Draw(d As Single, r As Single, dw As Single, color As OLE_COLOR)

Dim a

'a : زاويه
'تبديل ساعت يا دقيقه يا ثانيه به درجه
a = d * 6

'معكوس كردن جهت مثلثاتي در جهت عقربه ساعت و افزودن 90 درجه براي شروع از بالا
a = (360 - a) + 90

'تبديل درجه به راديان
a = a * 3.14 / 180

p.DrawWidth = 1
p.ForeColor = color

'رسم دايره ساعت
p.Circle (0, 0), 40, 0
p.Circle (0, 0), 45, 0

'r : طول عقربه
p.DrawWidth = dw
p.Line (0, 0)-(r * Cos(a), r * Sin(a))

End Sub

Private Sub Timer1_Timer()

p.Cls

Draw Hour(Now) * 5, 25, 12, vbBlue
Draw Minute(Now), 30, 8, vbGrayed
Draw Second(Now), 35, 4, vbRed

End Sub


r ميشه طول عقربه
x هم زاويه هست كه اونم بايد بدست بياد البته به واحد راديان نه درجه

چون يك دقيقه 60 ثانيه هست و يك دور كامل دايره مثلثاتي 360 درجه پس هر ثانيه ميشه 360/60 يعني 6 درجه پس بايد ثانيه يا دقيقه * 6 بشه
با توضيحات داده شده براي 10 ثانيه زاويه ميشه 10*6 يعني 60 درجه براي 20 دقيقه ميشه 20*6 يعني 120 درجه و براي 7 ساعت ميشه 7*5*6 يعني 210 درجه
ساعت ضربدر 5 هم شده چون كلا 60 واحد دقيقه و 60 واحد ثانيه داريم ولي فقط 12 واحد ساعت داريم بنابراين هر ساعت معادل 5 واحد هست

در توابع مثلثاتي مثل سينوس و كسينوس و ... زاويه در خلاف جهت عقربه ساعت هست پس براي اينكه برعكس و در جهت عقربه هاي ساعت باشه بايد 360 منهاي زاويه مورد نظر بشه از طرفي زاويه 0 مثلثاتي از خط افق (خاكستري) شروع ميشه ولي براي ساعت از بالا (عدد 12 يعني 90 درجه) بايد شروع بشه پس بايد زاويه رو به اضافه 90 درجه هم كنيم

تابع Draw يك عقربه رو رسم مي كنه هنگام فراخواني پارامتر اول يعني d عدد ثانيه يا دقيقه يا ساعت هست و البته براي ساعت بايد ضربدر 5 بشه

پارامتر دوم يعني r طول عقربه ميشه
پارامتر سوم يعني dw قطر عقربه
پارامتر چهارم يعني color رنگ عقربه

البته اينجا اصول كار آموزش داده شده و شما مي‌تونيد بهش شاخ و برگ بديد و ساعتتون رو زيبا كنيد
يك تايمر با Interval = 500 هم روي فرم بزاريد

[knight-rak]

هنوز نخوندمش ولی در هر حال خدا خیرت بده حداقل یکی پیدا شد توضیحات تصویری بده که چیزی مبهم نمونه ( البته اگر بازم ابهامی برام پیش اومد مزاحمتون میشم )

فعلا وقت ندارم ایشالا وقت پیدا کردم

خیلی خیلی مرسی

موفق باشید ....