سوال: غیرفعال کردن alt+enter ویندوز [بایگانی]

parselearn

شنبه 28 اسفند 1389, 19:32 عصر

با اين كد ميتونيد alt رو غير فعال كنيد (مسلما ديگر alt+enter وجود نداره!)

' -----------------------------
' Form1
' -----------------------------

Option Explicit

Private Sub Form_Load()
hhkLowLevelKybd = SetWindowsHookEx(WH_KEYBOARD_LL, AddressOf LowLevelKeyboardProc, App.hInstance, 0)
End Sub

Private Sub Form_Unload(Cancel As Integer)
If hhkLowLevelKybd <> 0 Then UnhookWindowsHookEx hhkLowLevelKybd
End Sub

' -----------------------------
' Module1
' -----------------------------

Option Explicit

Public Declare Function SetWindowsHookEx Lib "user32" _
Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As Long, _
ByVal hmod As Long, ByVal dwThreadId As Long) As Long
Public Declare Function CallNextHookEx Lib "user32" _
(ByVal hHook As Long, ByVal nCode As Long, ByVal wParam As Long, _
lParam As Any) As Long
Public Declare Function UnhookWindowsHookEx Lib "user32" _
(ByVal hHook As Long) As Long
Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
(Destination As Any, Source As Any, ByVal Length As Long)
Public Declare Function GetAsyncKeyState Lib "user32" _
(ByVal vKey As Long) As Integer

Public Const WH_KEYBOARD_LL = 13
Public Const HC_ACTION = 0
Public Const WM_KEYDOWN = &H100
Public Const WM_KEYUP = &H101
Public Const WM_SYSKEYDOWN = &H104
Public Const WM_SYSKEYUP = &H105
Public Const VK_CTRL = &H11
Public Const VK_ALT = &H12

Public Type KBDLLHOOKSTRUCT
vkCode As Long
scancode As Long
flags As Long
time As Long
dwExtraInfo As Long
End Type

Public hhkLowLevelKybd As Long

Public Function LowLevelKeyboardProc(ByVal nCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Dim kybd As KBDLLHOOKSTRUCT
Dim number As String

If (nCode = HC_ACTION) Then
If wParam = WM_KEYDOWN Or wParam = WM_SYSKEYDOWN Or wParam = WM_KEYUP Or wParam = WM_SYSKEYUP Then
CopyMemory kybd, ByVal lParam, LenB(kybd)
If (GetAsyncKeyState(VK_ALT)) < 0 Then
LowLevelKeyboardProc = -1
Exit Function
End If
End If
End If

LowLevelKeyboardProc = CallNextHookEx(hhkLowLevelKybd, nCode, wParam, ByVal lParam)
End Function