جلوگیری از هنگ برنامه در هنگام جستجوی فایل

[shahabbasic]

میخواستم بدونم که راهی هست که وقتی این کد رو توی یک ماژول قرار میدم

Public Declare Function SearchTreeForFile Lib "imagehlp" (ByVal RootPath As String, ByVal InputPathName As String, ByVal OutputPathBuffer As String) As Long

Public Const MAX_PATH = 260

و این کد رو هم توی یک کلید
Dim TempStr As String

Dim Result As Long

(TempStr = String(MAX_PATH, 0

(Result = SearchTreeForFile("C:\", "Ali.txt", TempStr

If Result <> 0 Then

(MsgBox "Located file at " + Left$(TempStr, InStr(1, TempStr, Chr$(0)) - 1

Else

"!MsgBox "File not found

End If

End Sub

برای جستجوی فایل برنامه تا موقعی که داره دنبال فایل میگرده هنگ نکنه و مثل بقیه برنامه تا موقع پایان جستجو یک پروسس بار بیاد تا پیشرفت کار رو نشون بده البته اضافه کردن پروسس بار و کارکردن با اون کاری نداره ولی یک راهی بگید تا برنامه هنگ نکنه

[butterfly8528]

سلام دوست عزیز .
اول اینکه لطفا بخش مناسبی رو واسه ایجاد تاپیک انتخاب کنید !
فقط کد زیر رو داخل یک فرم بریزید و پروژه را اجرا کنید و بر روی دکمه Search کلیک کنید :
'www.arshamsoft.com

Option Explicit

Dim WithEvents Command1 As VB.CommandButton

Dim WithEvents text1 As VB.TextBox
Dim WithEvents text2 As VB.TextBox
Dim WithEvents text3 As VB.TextBox
Dim WithEvents text4 As VB.TextBox

Dim WithEvents list1 As VB.ListBox


Dim WithEvents lblAbout As VB.Label

Private Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" (ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" (ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function GetFileAttributes Lib "kernel32" Alias "GetFileAttributesA" (ByVal lpFileName As String) As Long
Private Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long

Const MAX_PATH = 260
Const MAXDWORD = &HFFFF
Const INVALID_HANDLE_VALUE = -1
Const FILE_ATTRIBUTE_ARCHIVE = &H20
Const FILE_ATTRIBUTE_DIRECTORY = &H10
Const FILE_ATTRIBUTE_HIDDEN = &H2
Const FILE_ATTRIBUTE_NORMAL = &H80
Const FILE_ATTRIBUTE_READONLY = &H1
Const FILE_ATTRIBUTE_SYSTEM = &H4
Const FILE_ATTRIBUTE_TEMPORARY = &H100

Private Type FILETIME
dwLowDateTime As Long
dwHighDateTime As Long
End Type

Private Type WIN32_FIND_DATA
dwFileAttributes As Long
ftCreationTime As FILETIME
ftLastAccessTime As FILETIME
ftLastWriteTime As FILETIME
nFileSizeHigh As Long
nFileSizeLow As Long
dwReserved0 As Long
dwReserved1 As Long
cFileName As String * MAX_PATH
cAlternate As String * 14
End Type
Function StripNulls(OriginalStr As String) As String
If (InStr(OriginalStr, Chr(0)) > 0) Then
OriginalStr = Left(OriginalStr, InStr(OriginalStr, Chr(0)) - 1)
End If
StripNulls = OriginalStr
End Function

Function FindFilesAPI(path As String, SearchStr As String, FileCount As Integer, DirCount As Integer)
'KPD-Team 1999
'E-Mail: KPDTeam@Allapi.net
'URL: http://www.allapi.net/

Dim FileName As String ' Walking filename variable...
Dim DirName As String ' SubDirectory Name
Dim dirNames() As String ' Buffer for directory name entries
Dim nDir As Integer ' Number of directories in this path
Dim i As Integer ' For-loop counter...
Dim hSearch As Long ' Search Handle
Dim WFD As WIN32_FIND_DATA
Dim Cont As Integer
If Right(path, 1) <> "\" Then path = path & "\"
' Search for subdirectories.
nDir = 0
ReDim dirNames(nDir)
Cont = True
hSearch = FindFirstFile(path & "*", WFD)
If hSearch <> INVALID_HANDLE_VALUE Then
Do While Cont
DoEvents
DirName = StripNulls(WFD.cFileName)
' Ignore the current and encompassing directories.
If (DirName <> ".") And (DirName <> "..") Then
' Check for directory with bitwise comparison.
If GetFileAttributes(path & DirName) And FILE_ATTRIBUTE_DIRECTORY Then
dirNames(nDir) = DirName
DirCount = DirCount + 1
nDir = nDir + 1
ReDim Preserve dirNames(nDir)
End If
End If
Cont = FindNextFile(hSearch, WFD) 'Get next subdirectory.
Loop
Cont = FindClose(hSearch)
End If
' Walk through this directory and sum file sizes.
hSearch = FindFirstFile(path & SearchStr, WFD)
Cont = True
If hSearch <> INVALID_HANDLE_VALUE Then
While Cont
DoEvents
FileName = StripNulls(WFD.cFileName)
If (FileName <> ".") And (FileName <> "..") Then
FindFilesAPI = FindFilesAPI + (WFD.nFileSizeHigh * MAXDWORD) + WFD.nFileSizeLow
FileCount = FileCount + 1
list1.AddItem path & FileName
End If
Cont = FindNextFile(hSearch, WFD) ' Get next file
Wend
Cont = FindClose(hSearch)
End If
' If there are sub-directories...
If nDir > 0 Then
' Recursively walk into them...
For i = 0 To nDir - 1
FindFilesAPI = FindFilesAPI + FindFilesAPI(path & dirNames(i) & "\", SearchStr, FileCount, DirCount)
Next i
End If
End Function



Private Sub Form_Load()
Me.Width = 8835
Me.Height = 5200

'''' listbox
Set list1 = Controls.Add("VB.ListBox", "list1", Me)
list1.Move 0, 0
list1.Width = Me.Width - 150
list1.Height = 2000
list1.Visible = True




'''' Command Button
Set Command1 = Controls.Add("VB.CommandButton", "Command1", Me)
Command1.Move 7450, 4100
Command1.Caption = "Search"
Command1.Visible = True


'''' TextBox's

Set text1 = Controls.Add("VB.TextBox", "text1", Me)
text1.Width = Me.Width - 200
text1.Move 30, 1900
text1.Text = "C:\"
text1.Visible = True

Set text2 = Controls.Add("VB.TextBox", "text2", Me)
text2.Width = Me.Width - 200
text2.Move 30, 2430
text2.Text = "*.bmp"
text2.Visible = True


Set text3 = Controls.Add("VB.TextBox", "text3", Me)
text3.Width = Me.Width - 200
text3.Move 30, 2960
text3.Text = ""
text3.BackColor = &HE0E0E0
text3.Enabled = False
text3.Visible = True


Set text4 = Controls.Add("VB.TextBox", "text4", Me)
text4.Width = Me.Width - 200
text4.Move 30, 3460
text4.Text = ""
text4.BackColor = &HE0E0E0
text4.Enabled = False
text4.Visible = True



'''' label
Set lblAbout = Controls.Add("VB.Label", "lblAbout", Me)
lblAbout.AutoSize = True
lblAbout.FontSize = 10
lblAbout.FontBold = True
lblAbout.ForeColor = vbBlue

lblAbout.Move 60, 4100
lblAbout.Caption = "www.arshamsoft.com"
lblAbout.Visible = True

End Sub


Private Sub Command1_click()

Dim SearchPath As String, FindStr As String
Dim FileSize As Long
Dim NumFiles As Integer, NumDirs As Integer
Screen.MousePointer = vbHourglass
Me.Caption = "Searching,Please Wait..."
Command1.Enabled = False
text3.Text = "": text4.Text = ""
list1.Clear

SearchPath = text1.Text
FindStr = text2.Text
FileSize = FindFilesAPI(SearchPath, FindStr, NumFiles, NumDirs)
text3.Text = NumFiles & " Files found in " & NumDirs + 1 & " Directories"
text4.Text = "Size of files found under " & SearchPath & " = " & Format(FileSize, "#,###,###,##0") & " Bytes"

Command1.Enabled = True
Screen.MousePointer = vbDefault
Me.Caption = "Search Complete."
End Sub



Private Sub lblAbout_click()
Shell "explorer.exe http://www.arshamsoft.com", vbMaximizedFocus
End Sub



موفق باشید :لبخندساده:

[shahabbasic]

با عرض پوزش درسته که با این کد هنگ نمیکنه ولی این سورس هیچ فایلی پیدا نمیکنه انگار برای جستجو کد نویسی نشده

[butterfly8528]

با عرض پوزش درسته که با این کد هنگ نمیکنه ولی این سورس هیچ فایلی پیدا نمیکنه انگار برای جستجو کد نویسی نشده
دوست عزیز من حتی اشیاء مورد نیاز رو هم با کد نویسی ایجاد کردم که که شما این کار رو دستی انجام ندید ! کد های پست قبلیم رو در فرم کپی کنید و پروژه رو اجرا کنید و بر روی دکمه Search کلیک کنید ، همین !
http://up1.iranblog.com/images/79API_Search.gif
اگه باز هم موفق نشدید بگید که در قالب پروژه بدم بهتون .
موفق باشید :لبخندساده:

[setroyd]

اینم سورسش امیدوارم کمکت کنه

[shahabbasic]

فکر کنم مشکل حل شد تشکر