تغییر آیکن فرمها و گزارشات از طریق منوی Startup با کدvba

[aromega65]

سلام به همه دوستان و اساتید
سال نو مبارک
یه مشکل تقریبا مهم تو برنامه های من وجود داره
همونطور که میدونید از طریق منوی startup(در اکسس2003)میشه برای فرمها و گزارشات برنامه آیکنی بجز آیکن اکسس نمایش داد.
حالا من میخوام یه آیکن رو همراه فایل برنامه بزارم و آیکن برنامه از اونجا خونده بشه
ولی متاسفانه نه آدرس http رو قبول میکنه و نه آدرسهایی مانند Curentdb.path\msn.ico
من جستجو کردم ولی در مورد این مشکل چیزی پیدا نکردم
اگه دوستان و اساتیدبا نمونه یا کد اطلاعی دارند لطفا راهنمایی کنند
844998450084501

[Abbas Amiri]

با سلام وتبریک سال نو
روشی که در ذیل ارایه میشود را بنده در برنامه هایم استفاده میکنم کدهای زیر را دریک ماژول کپی کنید


Function StartUpActions()
DoCmd.ShowToolbar "Ribbon", acToolbarNo
DoCmd.SelectObject acTable, , True
DoCmd.RunCommand acCmdWindowHide
SetOption "Show Status Bar", False
StartUpProps "AppIcon", "Arm3.ico"
'FixBrokenRefrences
End Function


Function StartUpProps(strPropName As String, Optional varPropValue As Variant, _
Optional ddlRequired As Boolean) As Variant
Dim dbs As DAO.Database, prp As DAO.Property, varPropType As Variant
Const conPropNotFoundError = 3270

If IsMissing(ddlRequired) Then
ddlRequired = False
End If
varPropType = dbBoolean
Select Case strPropName
Case "StartupForm", "AppTitle"
varPropType = dbText
Case "AppIcon"
varPropType = dbText
varPropValue = CurrentProject.Path & "\Icons\" & CStr(varPropValue)
End Select
Set dbs = CurrentDb

If Not IsMissing(varPropValue) Then
On Error GoTo AddProps_Err
dbs.Properties(strPropName) = varPropValue
StartUpProps = True
Else
On Error GoTo NotFound_Err
StartUpProps = dbs.Properties(strPropName)
End If

StartupProps_End:
On Error Resume Next
Set dbs = Nothing
Set prp = Nothing
Exit Function
AddProps_Err:
If Err = conPropNotFoundError Then
' Property not found when adding a property value.
Set prp = dbs.CreateProperty(strPropName, varPropType, _
varPropValue, ddlRequired)
dbs.Properties.Append prp
Resume Next
Else
' Unknown error.
StartUpProps = False
Resume StartupProps_End
End If
NotFound_Err:
If Err = conPropNotFoundError Then
' Property not found when returning a property value.
StartUpProps = Null
Resume Next
Else
' Unknown error.
StartUpProps = False
Resume StartupProps_End
End If

End Function


اگر ماکرو AutoExec ندارید آنرا بسازید و مطابق زیر عمل وآنرا ذخیره کنید. برنامه در استارت آپ کدهای مشخص شده را اجراخواهدکرد. در پوشه جاری باید یک فولدر بنام Icons بسازید و آیکون مورد نظر را درآن قراردهید

[aromega65]

کارت درست آقای امیری:قلب:
واقعا این یکی کلافم کرده بود

[Rasool-GH]

با عرض سلام و تبريك سال نو خدمت دوستان عزيز
جسارتا اگر سوال شما رو درست متوجه شده باشم . در قسمت Application Icon فقط كافيه اسم ايكن رو وارد كنيد و داخل پوشه برنامه يك ايكن با همون نام داشته باشيد مثلا وارد كنيد msn.ico و همين ايكن رو كنار برنامه قرار بدين

[laia56]

با سلام ایا چنین کدی را برای آیکن روی دسکتاپ هم میشود استفاده کرد

[Abbas Amiri]

باسلام درجواب باید بگویم خیر . در جستجوی پیشرفته SysTray را در تالار اکسس جستجو کنید

[laia56]

باسلام درجواب باید بگویم خیر . در جستجوی پیشرفته SysTray را در تالار اکسس جستجو کنید

دوست عزیز با سلام نمیدانم چرا در جستجوی پیشرفته دوباره به همین تایپیک میرسم اگر جنابعالی تایپیک دیگری را مورد نظرتان هست لطفا لینک انرا بگذارید
با تشکر از لطف شما

[Abbas Amiri]

لینک زیر پست شماره 4
http://barnamenevis.org/showthread.php?277515-%D9%86%D9%85%D8%A7%D9%8A%D8%B4-%D8%A2%D9%8A%D9%83%D9%86-%D8%A8%D8%B1%D9%86%D8%A7%D9%85%D9%87-%D9%88-%D8%A8%D8%A7%D9%84%D9%88%D9%86-%D9%85%D8%B1%D8%A8%D9%88%D8%B7%D9%87-%D8%AF%D8%B1-Taskbar-%D9%88%D9%8A%D9%86%D8%AF%D9%88%D8%B2&highlight=%D8%A8%D8%A7%D9%84%D9%88%D9%86

[Profesorjd]

با سلام و تشکر
دوست گرامی ! در فایل ضمیمه علت عدم اجرا را بفرمایید .

[Abbas Amiri]

دلیل همنام بودن ماژول و تابع هست نام ماژول را تغییردهید مثلا basStartupActions