شبیه سازی spelling and geramer برنامه ورد در vb6

[farghabil]

اقا کی میدونه چطوری میشه اسپیلینگ گرامر(spelling and geramer) ورد را در وی بی 6 شبیه سازی کرد؟کمک کنید لطفا

[butterfly8528]

سلام دوست عزیز .

یک عدد Command Button و یک عدد TextBox بزار رو فرمت و از کد زیر استفاده کن :



Option Explicit

Private Declare Function CoAllowSetForegroundWindow Lib "ole32.dll" (ByVal pUnk As Object, ByVal lpvReserved As Long) As Long

Private Sub Command1_Click()
Dim oWord As Object
Dim oTmpDoc As Object
Dim lOrigTop As Long

' Create a Word document object
Set oWord = CreateObject("Word.Application")

CoAllowSetForegroundWindow oWord, 0

Set oTmpDoc = oWord.Documents.Add
' Position Word off screen to avoid having document visible
lOrigTop = oWord.Top
oWord.WindowState = 0
oWord.Top = -3000

oWord.Visible = True
oWord.Activate

' Copy the contents of the text box to the clipboard
Text1.SelStart = 0
Text1.SelLength = Len(Text1.Text)
Clipboard.Clear
Clipboard.SetText Text1.SelText

' Assign the text to the document and check spelling

With oTmpDoc
.Content.Paste
.Activate
.CheckSpelling

' After the user has made changes, use the clipboard to
' transfer the contents back to the text box
.Content.Copy
Text1.Text = Clipboard.GetText(vbCFText)
' Close the document and exit Word
.Saved = True
.Close
End With
Set oTmpDoc = Nothing

oWord.Visible = False

oWord.Top = lOrigTop
oWord.Quit
Set oWord = Nothing
End Sub



حالا یک کلمه اشتباه مثل Textt رو تو تکست باکست بنویس و بعد رو دکمه کلیک کن :لبخندساده:.
منبع (http://support.microsoft.com/kb/243844)
موفق باشید .

[farghabil]

دوست عزیز دست گلت درد نکنهو ببخشید دیر اومدم تشکر کردم. ایشالا توشادیا جبران کنیم:لبخندساده:

[farghabil]

آقا ببخشید وقتی برنامه رو اجرا میکنم error میده. مینویسه : activex Component Cant creat object
باید چیکار کنم؟ مشکل کجاست؟

[butterfly8528]

سلام .

دوست عزیز دست گلت درد نکنهو ببخشید دیر اومدم تشکر کردم. ایشالا توشادیا جبران کنیم:لبخندساده:
خواهش می کنم ، لطفا برای تشکر کردن فقط از دکمه تشکر استفاده کنید و از ایجاد پست برای این منظور خودداری کنید .


آقا ببخشید وقتی برنامه رو اجرا میکنم error میده. مینویسه : activex Component Cant creat object
باید چیکار کنم؟ مشکل کجاست؟ نرم افزار MS Word رو سیستمتون نصب شده ؟