جابجایی فرم

[hosein320]

سلام
تو وی بی 6 یه کنترل بود که وقتی میگرفتیش میتونستی فرم رو حرکت بدی
اسم این کنترل برای دات نت چیه؟:متفکر::متفکر:

[SHD.NET]

سلام

تو وی بی 6 یه کنترل بود که وقتی میگرفتیش میتونستی فرم رو حرکت بدی
من یادم نمیاد توی وی بی6 همیچین چیزی دیده باشم، میشه یگین اسمش چی بود ؟؟

[hosein320]

اتفاقا خودمم یادم نمیاد اسمش چی بود:لبخند:
ولی باهاش کار کردم
به جای اینکه بالای فرم رو بگیری و فرم رو حرکت بدی
کنترل رو میگیری و فرم رو حرکت میدی

[hosein320]

کسی نمیدونه:ناراحت:

[the king]

کسی نمیدونه:ناراحت:

یک کلاس جدید به پروژه تون اضافه کنید :

Public Class DragForm
Inherits System.Windows.Forms.Control

Private Const HTCAPTION As Int32 = 2
Private Const WM_NCLBUTTONDOWN As Int32 = &HA1

Private Declare Function ReleaseCapture Lib "user32.dll" () As Int32
Private Declare Function SendMessage Lib "user32.dll" Alias "SendMessageA" (ByVal hwnd As Int32, ByVal wMsg As Int32, ByVal wParam As Int32, ByVal lParam As Int32) As Int32

Public Sub New()
SetStyle(ControlStyles.FixedWidth Or ControlStyles.FixedHeight, True)
SetStyle(ControlStyles.Selectable, False)
Me.MinimumSize = New Size(32, 32)
Me.MaximumSize = New Size(32, 32)
End Sub

Protected Overrides ReadOnly Property DefaultSize() As System.Drawing.Size
Get
Return New Size(32, 32)
End Get
End Property

Protected Overrides Sub OnPaint(ByVal e As System.Windows.Forms.PaintEventArgs)
e.Graphics.Clear(Me.BackColor)
e.Graphics.DrawIcon(SystemIcons.WinLogo, New Rectangle(0, 0, 32, 32))
End Sub

Protected Overrides Sub OnMouseDown(ByVal e As System.Windows.Forms.MouseEventArgs)
MyBase.OnMouseDown(e)
ReleaseCapture()
SendMessage(Me.FindForm.Handle.ToInt32(), WM_NCLBUTTONDOWN, HTCAPTION, 0)
End Sub
End Class


وقتی پروژه رو کامپایل کردید بالاترین قسمت Toolbox یک آیتم جدید DragForm اضافه شده.
یک نمونه اش را روی فرم تان قرار دهید.

[SHD.NET]

سلام . این تاپیک رو خودم قبلا ایجاد کرده بودم، برای حرکت دادن فرم،
حرکت دادن فرم در حالت None + حرکت دادن آبجکت روی فرم (http://barnamenevis.org/showthread.php?375295-%D8%AD%D8%B1%DA%A9%D8%AA-%D8%AF%D8%A7%D8%AF%D9%86-%D9%81%D8%B1%D9%85-%D8%AF%D8%B1-%D8%AD%D8%A7%D9%84%D8%AA-None-%D8%AD%D8%B1%DA%A9%D8%AA-%D8%AF%D8%A7%D8%AF%D9%86-%D8%A2%D8%A8%D8%AC%DA%A9%D8%AA-%D8%B1%D9%88%DB%8C-%D9%81%D8%B1%D9%85)

**موفق باشید**