دریافت اطلاعات کانکشن وایرلس

[roozbehkm]

با سلام خدمت اساتید محترم
من میخوام جزئیات وایفایی که بهش متصل هستم رو دریافت کنم
مثل SSID , Password , Signal , ...
خواهشا راهنمایی کنید
ممنونتون میشم :خجالت::قلب:

[Saman_12]

میتونی با یه batch file و CMD کارت رو راه بندازی این رو به عنوان نمونه نوشتم اطلاعات دیگه ای خواستی خودت اظافه کن :


@echo off


set IName=nul
set SSID=nul
set Password=nul
set Signal=nul
set Profile=nul


for /f "tokens=1,3,*" %%a in ('netsh wlan show interface') do (
if %%a==Name set "IName=%%b %%c"
if %%a==SSID set SSID=%%b
if %%a==Signal set Signal=%%b
if %%a==Profile set Profile=%%b
)


netsh wlan export profile interface="%IName%" name="%Profile%" folder=. key=clear


set "FileName=%IName%-%profile%.xml"
rename "%FileName%" "temp.xml"


setlocal EnableDelayedExpansion


for /f %%a in (temp.xml) do (
set substring=%%a
if "!substring:~1,11!"=="keyMaterial" set "Password=!Substring:~13,-14!"
)


setlocal DisableDelayedExpansion


del /q temp.xml


echo Interface:%IName% > ProfileInfo.txt
echo Profile:%Profile% >> ProfileInfo.txt
echo SSID:%SSID% >> ProfileInfo.txt
echo Password:%Password% >> ProfileInfo.txt
echo Signal:%Signal% >> ProfileInfo.txt

یکم به نظر بد میاد که اطلاعات باید از فایل خونده بشن...

یه dl برای دانت هم هست که سورسش هم موجوده (گوگلش کن):
SimpleWifi .net