فرستادن ایمل

[mehdi1357]

با سلام خدمت دوستان
می خواهم با ویژوال برنامه ای بنویسم که اطلاعاتی را به یک ایمل بفرستد
متشکرم

[Sir.V65j]

دوست عزیز تو تک کلیک یه روش جالب معرفی کرده بودن اونم این بود اگه هاست داشته باشین یه فایل PHP رو اون آپلود کنین و با اون کارتون رو راه بندازین. اگه یه همچین روشی به دردتون می خوره بگین بیشتر توضیح بدم.

[شاپرک]

' You need to declare a reference to the Outlook library, and the filesystemobject.
' this is not as hard as it sounds.
'
' Look in the menu above, and click Tools, then select References
'
' Scroll down the list until you see
' Microsoft Scripting Runtime -- and put a check next to it (if one is not there already)
'
' Microsoft Outlook Object Library -- check that.
' There will be some version number there as well; it doesn't matter.
' This will work with Outlook98 and Outlook2000 and OutlookXP. It hasn't been tested on Outlook 2003 yet.

Public Subjectline As String
Public BodyFile As String
Public Attach As String


Public Function SendEMail()

Dim db As DAO.Database
Dim MailList As DAO.Recordset
Dim MyOutlook As Outlook.Application
Dim MyMail As Outlook.MailItem
'Dim Subjectline As String
'Dim BodyFile As String
Dim fso As FileSystemObject
Dim MyBody As TextStream
Dim MyBodyText As String

Set fso = New FileSystemObject

' First, we need to know the subject.
' We can't very well be sending around blank messages...

Subjectline$ = InputBox$("ãæÖæÚ Çíãíá ÑÇ æÇÑÏ ßäíÏ", _
"We Need A Subject Line!")

' If there's no subject, call it a day.

If Subjectline$ = "" Then
MsgBox "No subject line, no message." & vbNewLine & vbNewLine & _
"Quitting...", vbCritical, "E-Mail Merger"
Exit Function
End If

' Now we need to put something in our letter...

BodyFile$ = InputBox$("ÈÏäå ÇíãíáÊÇä ÑÇ ÏÑ íß ÝÇíá ÊßÓÊ ÐÎíÑå æ ãÓíÑ Âä ÑÇ ÇíäÌÇ æÇÑÏ ßäíÏ :", _
"We Need A Body!")




' If there's nothing to say, call it a day.

If BodyFile$ = "" Then
MsgBox "No body, no message." & vbNewLine & vbNewLine & _
"Quitting...", vbCritical, "I Ain't Got No-Body!"
Exit Function
End If

' Check to make sure the file exists...
If fso.FileExists(BodyFile$) = False Then
MsgBox "The body file isn't where you say it is. " & vbNewLine & vbNewLine & _
"Quitting...", vbCritical, "I Ain't Got No-Body!"
Exit Function
End If

' Since we got a file, we can open it up.
Set MyBody = fso.OpenTextFile(BodyFile, ForReading, False, TristateUseDefault)

' and read it into a variable.
MyBodyText = MyBody.ReadAll

' and close the file.
MyBody.Close

' Now, we open Outlook for our own device..
Set MyOutlook = New Outlook.Application


' Set up the database and query connections

Set db = CurrentDb()

Set MailList = db.OpenRecordset("MyEmailAddresses")

' now, this is the meat and potatoes.
' this is where we loop through our list of addresses,
' adding them to e-mails and sending them.

Do Until MailList.EOF

' This creates the e-mail

Set MyMail = MyOutlook.CreateItem(olMailItem)

' This addresses it
MyMail.To = MailList("email")

'This gives it a subject
MyMail.Subject = Subjectline$

'This gives it the body
MyMail.Body = MyBodyText


'If you want to send an attachment
'uncomment the following line

MyMail.Attachments.Add Attach, olByValue, 1, "My Displayname"
MyMail.Attachments.Add Attach, olByValue, 1, "My Displayname2"

' To briefly describe:
' "c:\myfile.txt" = the file you want to attach
'
' olByVaue = how to pass the file. olByValue attaches it, olByReference creates a shortcut.
' the shortcut only works if the file is available locally (via mapped or local drive)
'
' 1 = the position in the outlook message where to attachment goes. This is ignored by most
' other mailers, so you might want to ignore it too. Using 1 puts the attachment
' first in line.
'
' "My Displayname" = If you don't want the attachment's icon string to be "c:\myfile.txt" you
' can use this property to change it to something useful, i.e. "4th Qtr Report"



'This sends it!
MyMail.Send

'Some people have asked how to see the e-mail
'instead of automaticially sending it.
'Uncomment the next line
'And comment the "MyMail.Send" line above this.

' MyMail.Display



'And on to the next one...
MailList.MoveNext

Loop

'Cleanup after ourselves

Set MyMail = Nothing


'Uncomment the next line if you want Outlook to shut down when its done.
'Otherwise, it will stay running.

'MyOutlook.Quit
Set MyOutlook = Nothing

MailList.Close
Set MailList = Nothing
db.Close
Set db = Nothing

End Function

[vbhamed]

سلام
چطوری میشه با فایل php این کار رو کرد ؟
لطفا اگه میشه دقیقا مراحل رو توضیح بدین

[ebrahimhoze]

اگه سورس کدی در مورد فرستادن فایل به ایمیل تو وی بی خواستی توی تاپیک من پیدا میکنی ( بگرد )
http://barnamenevis.org/forum/showthread.php?t=75188