خواندن نتیجه ی برگشتی حاصل از دستورات cmd با تابع shell

[__siavash__]

سلام
من با تابع shell بعضی از دستورات command prompt رو اجرا می کنم.
البته دستوراتی که عملی رو انجام می دهند مثل
shell "Attrib +s +h" & name file, vbhide
که یه فایل رو به فایل سیستمی تبدیل میکنه.
اما
دستوراتی مثل net statistics workstation در cmd.exe که زمان روشن شدن رو بر میگردونه چه جوری میتونم نتیجه دستور رو که در cmd نمایش داده میشه مثلا توی یه تکس باکس نشون بدم
shell "net statistics workstation" ,vbnormalfocus

[S_VB.max]

یک Command Button و دو تا Text Box روی فرمت بذار و خاصیت Multiline تکست باکس دومی رو به Trueتنظیم کن.
حالا کد زیر را در فرم کپی کن:

Option Explicit
Private Declare Function CreatePipe Lib "kernel32" (phReadPipe As Long, phWritePipe As Long, lpPipeAttributes As SECURITY_ATTRIBUTES, ByVal nSize As Long) As Long
Private Declare Sub GetStartupInfo Lib "kernel32" Alias "GetStartupInfoA" (lpStartupInfo As STARTUPINFO)
Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" (ByVal lpApplicationName As String, ByVal lpCommandLine As String, lpProcessAttributes As Any, lpThreadAttributes As Any, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, lpEnvironment As Any, ByVal lpCurrentDriectory As String, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long
Private Declare Function SetWindowText Lib "user32" Alias "SetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String) As Long
Private Declare Function ReadFile Lib "kernel32" (ByVal hFile As Long, lpBuffer As Any, ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long, lpOverlapped As Any) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

Private Type SECURITY_ATTRIBUTES
nLength As Long
lpSecurityDescriptor As Long
bInheritHandle As Long
End Type

Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessId As Long
dwThreadId As Long
End Type

Private Type STARTUPINFO
cb As Long
lpReserved As Long
lpDesktop As Long
lpTitle As Long
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Byte
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type

Private Type OVERLAPPED
ternal As Long
ternalHigh As Long
offset As Long
OffsetHigh As Long
hEvent As Long
End Type

Private Const STARTF_USESHOWWINDOW = &H1
Private Const STARTF_USESTDHANDLES = &H100
Private Const SW_HIDE = 0
Private Const EM_SETSEL = &HB1
Private Const EM_REPLACESEL = &HC2

Private Sub Command1_Click()
Command1.Enabled = False
Redirect Text1.Text, Text2
Command1.Enabled = True
End Sub
Private Sub Form_Load()
Text1.Text = "ping"
End Sub
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
If Command1.Enabled = False Then Cancel = True
End Sub

Sub Redirect(cmdLine As String, objTarget As Object)
Dim i%, t$
Dim pa As SECURITY_ATTRIBUTES
Dim pra As SECURITY_ATTRIBUTES
Dim tra As SECURITY_ATTRIBUTES
Dim pi As PROCESS_INFORMATION
Dim sui As STARTUPINFO
Dim hRead As Long
Dim hWrite As Long
Dim bRead As Long
Dim lpBuffer(1024) As Byte
pa.nLength = Len(pa)
pa.lpSecurityDescriptor = 0
pa.bInheritHandle = True

pra.nLength = Len(pra)
tra.nLength = Len(tra)

If CreatePipe(hRead, hWrite, pa, 0) > 0 Then
sui.cb = Len(sui)
GetStartupInfo sui
sui.hStdOutput = hWrite
sui.hStdError = hWrite
sui.dwFlags = STARTF_USESHOWWINDOW Or STARTF_USESTDHANDLES
sui.wShowWindow = SW_HIDE
If CreateProcess(vbNullString, cmdLine, pra, tra, True, 0, Null, vbNullString, sui, pi) > 0 Then
SetWindowText objTarget.hwnd, ""
Do
Erase lpBuffer()
If ReadFile(hRead, lpBuffer(0), 1023, bRead, ByVal 0) Then
SendMessage objTarget.hwnd, EM_SETSEL, -1, 0
SendMessage objTarget.hwnd, EM_REPLACESEL, False, lpBuffer(0)
DoEvents
Else
CloseHandle pi.hThread
CloseHandle pi.hProcess
Exit Do
End If
CloseHandle hWrite
Loop
CloseHandle hRead
End If
End If
End Sub


یعنی با این کدها می تونی دستورات Dos رو از توی برنامه خودت اجرا کنی و خروجی دستورات رو در یک Text Box ببینی.
نکته: اجرای این کدها برای بعضی دستورات در ویندوزهای 95، 98 و ME ممکنه به قفل کردن سیستم منجر بشه.

[__siavash__]

S_VB.max (http://barnamenevis.org/forum/member.php?u=16439)
دستت درد نکنه
من کد رو کپی کردم و جواب داد اما اصلا از طرز کار کد سر در نیاوردم
راه ساده تری نیست؟
بازم ممنون

[MM_Mofidi]

Command /Swicths >DestinationFilename.txt
بعد نتیجه را از فایل DestinationFilename.txt بخون
اینم یه راه

[__siavash__]

MM_Mofidi (http://barnamenevis.org/forum/member.php?u=5582)
من این کد رو توی cmd امتحان کردم, یه فایل تکست درست میکنه و دستورات وارد شده رو ثبت میکنه ولی نتیجه ی برگشتی رو ثبت نکرده بود ؟؟؟؟؟؟؟؟؟؟

[S_VB.max]

اینا امتحان کن


Shell "cmd.exe /c ping > DestinationFilename.txt"

[__siavash__]

S_Vb.max
کد شما خیلی قشنگ کار کرد و جواب داد
اما یه مشکلی دیگه اونم اینه که من چه جوری می تونم به مسیر مور نظرم برم مثلا تابع
Attrib +s +h که یه فایل رو به فایل سیستمی تبدیل میکنه به شرطی که تو اسمش Space نباشه !
خوب حالا اگه من بنویسم shell "Attrib +s +h" & name file, vbhide و به جای نام فایل مسیر فایل رو بدم مثلا (F:\user\test.txt) فایل test.txt سیستمی میشه ولی اگر مسیر این باشه کار نمی کنه (F:\user َAdmin\test.txt) به خاطر وجود space.
و اگه برنامه رو از کنار فایل اجرا کنم و این بار فقط نام فایل رو بدم اونوقت جواب میده !!!


من یه فایل گذاشتم اگه ممکنه یه نگاه بکن

[S_VB.max]

پیشنهاد می کنم برای تغییر صفت یک فایل یا پوشه از تابع SetFileAttributes استفاده کنید تا این درد سر را نداشته باشید
Private Const FILE_ATTRIBUTE_ARCHIVE = &H20
Private Const FILE_ATTRIBUTE_COMPRESSED = &H800
Private Const FILE_ATTRIBUTE_DIRECTORY = &H10
Private Const FILE_ATTRIBUTEHIDDEN = &H2
Private Const FILE_ATTRIBUTE_NORMAL = &H80
Private Const FILE_ATTRIBUTE_READONLY = &H1
Private Const FILE_ATTRIBUTE_SYSTEM = &H4

Private Declare Function SetFileAttributes Lib "kernel32.dll" Alias "SetFileAttributesA" (ByVal lpFileName As String, ByVal dwFileAttributes As Long) As Long

Private Sub Command1_Click()
SetFileAttributes "C:\New Folder", FILE_ATTRIBUTEHIDDEN
End Sub

[__siavash__]

S_VB.max
خیلی جالب بود ممنون :تشویق:

[lahij.ir]

مثلا من یه فایل attrib شده تو هاردم دارم میخوام اونو از حلت attrib خارجش کنم یعنی یه فایل معمولی بشه ، ب این وجود بازم میشه از این تابعی که معرفی کردین استفاده کرد ؟

[H4i0 ACP]

مثلا من یه فایل attrib شده تو هاردم دارم میخوام اونو از حلت attrib خارجش کنم یعنی یه فایل معمولی بشه ، ب این وجود بازم میشه از این تابعی که معرفی کردین استفاده کرد ؟
سلام
فکر کنم این باشه :
Private Const FILE_ATTRIBUTE_ARCHIVE = &H20
Private Const FILE_ATTRIBUTE_COMPRESSED = &H800
Private Const FILE_ATTRIBUTE_DIRECTORY = &H10
Private Const FILE_ATTRIBUTEHIDDEN = &H2
Private Const FILE_ATTRIBUTE_NORMAL = &H80
Private Const FILE_ATTRIBUTE_READONLY = &H1
Private Const FILE_ATTRIBUTE_SYSTEM = &H4

Private Declare Function SetFileAttributes Lib "kernel32.dll" Alias "SetFileAttributesA" (ByVal lpFileName As String, ByVal dwFileAttributes As Long) As Long

Private Sub Command1_Click()
SetFileAttributes "C:\New Folder", FILE_ATTRIBUTE_NORMAL

End Sub

[مهران رسا]

مثلا من یه فایل attrib شده تو هاردم دارم میخوام اونو از حلت attrib خارجش کنم یعنی یه فایل معمولی بشه ، ب این وجود بازم میشه از این تابعی که معرفی کردین استفاده کرد ؟



Shell "Attrib -s -h [FileName.FileType]"

[peach2]

ببخشید من چطور میتونم از طریق shell اینترنت ایکسپلورر رو اجرا کنم؟یا برنامه run رو اجرا کنم؟
ممنون میشه اگه جوابمو بدین

[IamOverlord]

سلام دوست عزیز!

ببخشید من چطور میتونم از طریق shell اینترنت ایکسپلورر رو اجرا کنم؟یا برنامه run رو اجرا کنم؟
ممنون میشه اگه جوابمو بدین
این کد رو امتحان کن:

Shell "explorer.exe http://google.com"