پیدا کردن نام کانکشن های موجود

[__siavash__]

سلام
من چه طوری میتونم نام کانکشن های موجود رو پیدا کنم و لیست کنم

[S_VB.max]

Private Type RAS_ENTRIES
dwSize As Long
szEntryname(256) As Byte
End Type
Private Declare Function RasEnumEntriesA Lib "rasapi32.dll" (ByVal reserved As String, ByVal lpszPhonebook As String, lprasentryname As Any, lpcb As Long, lpcEntries As Long) As Long

Public Sub ListDUNs(sDunList() As String)
Dim plSize As Long
Dim plEntries As Long
Dim psConName As String
Dim plIndex As Long
Dim RAS(255) As RAS_ENTRIES

Erase sDunList()
RAS(0).dwSize = 264
plSize = 256 * RAS(0).dwSize
Call RasEnumEntriesA(vbNullString, vbNullString, RAS(0), plSize, plEntries)
plEntries = plEntries - 1
If plEntries >= 0 Then
ReDim sDunList(plEntries)
For plIndex = 0 To plEntries
psConName = StrConv(RAS(plIndex).szEntryname(), vbUnicode)
sDunList(plIndex) = Left$(psConName, InStr(psConName, vbNullChar) - 1)
Next plIndex
End If
End Sub

Private Sub Form_Load()
Dim psDuns() As String
Dim piMax As Integer
Dim piIndex As Integer

ListDUNs psDuns
List1.Clear

piMax = -1
On Error Resume Next
piMax = UBound(psDuns())
On Error GoTo 0
For piIndex = 0 To piMax
List1.AddItem psDuns(piIndex)
Next piIndex

End Sub

[__siavash__]

S_VB.max (http://barnamenevis.org/forum/member.php?u=16439)
خیلی خیلی ممنون
فقط دو تا سوال دارم
یکی اینکه این تابع رو چه طوری دیکلر کردی من که اونو توی API Viewer پیدا نکردم یعنی نداشتش
دوم اینکه میخوام بدونم وقتی کاربر تو اینترنت هست با کدوم یکی از این کانکشن ها وصل شده ؟
Tanx