جستجوی OCX روی کامپیوتر

[majjjj]

چجوری باید اکتیو ایکس ها رو روی سیستم از طریق VB پیدا کرد

[majjjj]

کسی بلد نیست

[Hamid_PaK]

با روال FindFirst و FindNext که جزء API های ویندوز هست می توانید این کار را انجام دهید ...
یک راه دیگر هم می توانید از روی GUID اکتیوایس آدرس نصب شده آن را بیابید ...

یا حق ...

[CodeMasterX]

یا از توابع API که هممید جان هم نام برد استفاده کن (که توضیه میشه بخاطر سرعت خوبش) یا روی آی دی من جستجو کن یه برنامه گذاشتم برای جستجوی فولدر ها و فایل ها با آبجکت فایل سیستم.
در ضمن شما تاپیکت مربوط به جستجوی فایل ها و پوشه ها میشه که اگه جستجو میکردی جواب رو پیدا میکردی.

[majjjj]

با روال FindFirst و FindNext که جزء API های ویندوز هست می توانید این کار را انجام دهید ...
یک راه دیگر هم می توانید از روی GUID اکتیوایس آدرس نصب شده آن را بیابید ...

یا حق ...

دوست گرامی چجوری باید به این توابع دسترسی پیدا کنم

[CodeMasterX]

کد زیر رو تو قسمت General فرم وارد کن:



Private Const MAX_PATH = 260
Private Const MAXDWORD = &HFFFF
Private Const INVALID_HANDLE_VALUE = -1
Private Const FILE_ATTRIBUTE_ARCHIVE = &H20
Private Const FILE_ATTRIBUTE_DIRECTORY = &H10
Private Const FILE_ATTRIBUTE_HIDDEN = &H2
Private Const FILE_ATTRIBUTE_NORMAL = &H80
Private Const FILE_ATTRIBUTE_READONLY = &H1
Private Const FILE_ATTRIBUTE_SYSTEM = &H4
Private Const FILE_ATTRIBUTE_TEMPORARY = &H100

Private Type FILETIME
dwLowDateTime As Long
dwHighDateTime As Long
End Type

Private Type WIN32_FIND_DATA
dwFileAttributes As Long
ftCreationTime As FILETIME
ftLastAccessTime As FILETIME
ftLastWriteTime As FILETIME
nFileSizeHigh As Long
nFileSizeLow As Long
dwReserved0 As Long
dwReserved1 As Long
cFileName As String * MAX_PATH
cAlternate As String * 14
End Type

Private Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" (ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" (ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function GetFileAttributes Lib "kernel32" Alias "GetFileAttributesA" (ByVal lpFileName As String) As Long
Private Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long


همینطور دو تابع زیر رو :




Function StripNulls(OriginalStr As String) As String
If (InStr(OriginalStr, Chr(0)) > 0) Then
OriginalStr = Left(OriginalStr, InStr(OriginalStr, Chr(0)) - 1)
End If
StripNulls = OriginalStr
End Function

Function FindFilesAPI(path As String, SearchStr As String, FileCount As Integer, DirCount As Integer)
Dim FileName As String
Dim DirName As String
Dim dirNames() As String
Dim nDir As Integer
Dim i As Integer
Dim hSearch As Long
Dim WFD As WIN32_FIND_DATA
Dim Cont As Integer
If Right(path, 1) <> "\" Then path = path & "\"
nDir = 0
ReDim dirNames(nDir)
Cont = True
hSearch = FindFirstFile(path & "*", WFD)
If hSearch <> INVALID_HANDLE_VALUE Then
Do While Cont
DirName = StripNulls(WFD.cFileName)
If (DirName <> ".") And (DirName <> "..") Then
If GetFileAttributes(path & DirName) And FILE_ATTRIBUTE_DIRECTORY Then
dirNames(nDir) = DirName
DirCount = DirCount + 1
nDir = nDir + 1
ReDim Preserve dirNames(nDir)
End If
End If
Cont = FindNextFile(hSearch, WFD)
Loop
Cont = FindClose(hSearch)
End If
hSearch = FindFirstFile(path & SearchStr, WFD)
Cont = True
If hSearch <> INVALID_HANDLE_VALUE Then
While Cont
FileName = StripNulls(WFD.cFileName)
If (FileName <> ".") And (FileName <> "..") Then
FindFilesAPI = FindFilesAPI + (WFD.nFileSizeHigh * MAXDWORD) + WFD.nFileSizeLow
FileCount = FileCount + 1
List1.AddItem path & FileName
End If
Cont = FindNextFile(hSearch, WFD)
Wend
Cont = FindClose(hSearch)
End If
If nDir > 0 Then
For i = 0 To nDir - 1
FindFilesAPI = FindFilesAPI + FindFilesAPI(path & dirNames(i) & "\", SearchStr, FileCount, DirCount)
Next i
End If
End Function


حالا چهار تا TextBox و یه دکمه فرمان و یه لیست باکس به فرم اضافه کن و نام پیش فرضشون رو انتخاب همونجوری رها کن.تکست اولی نام فایل مورد نظر هست (که میتونه از دستورات شلویندوز هم پیروی کنه) و تکست دوم محل جستجو هست.
حالا توی دکمه فرمان کد زیر رو بنویس :



Dim SearchPath As String, FindStr As String
Dim FileSize As Long
Dim NumFiles As Integer, NumDirs As Integer

Screen.MousePointer = vbHourglass
List1.Clear
SearchPath = Text1.Text
FindStr = Text2.Text
FileSize = FindFilesAPI(SearchPath, FindStr, NumFiles, NumDirs)
Text3.Text = NumFiles & " Files found in " & NumDirs + 1 & " Directories"
Text4.Text = "Size of files found under " & SearchPath & " = " & Format(FileSize, "#,###,###,##0") & " Bytes"
Screen.MousePointer = vbDefault


مشکل حل شد ؟

[__siavash__]

یا از توابع API که هممید جان هم نام برد استفاده کن (که توضیه میشه بخاطر سرعت خوبش) یا روی آی دی من جستجو کن یه برنامه گذاشتم برای جستجوی فولدر ها و فایل ها با آبجکت فایل سیستم.
در ضمن شما تاپیکت مربوط به جستجوی فایل ها و پوشه ها میشه که اگه جستجو میکردی جواب رو پیدا میکردی.
لینک اون تاپیک اینه که S_VB.Max لینکشو دیروز گذاشتن!
http://www.barnamenevis.org/forum/showthread.php?t=65774