نمایش نتایج 1 تا 9 از 9

نام تاپیک: rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

  1. #1
    کاربر دائمی آواتار mazoolagh
    تاریخ عضویت
    اردیبهشت 1384
    سن
    71
    پست
    3,030

    rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

    سطح این آموزش بالاتر از متوسط است، لطفا پرسشهای ابتدایی را گوگل کنید!

    از آنجا که rss در اصل یک فایل xml هست، باید علاوه بر آشنایی با این نوع فایل، با روش های خواندن فایل از وب و همینجور نحوه پردازش اون آشنا باشین.

    دو تاپیک زیر میتونه به شما در فهمیدن کدها کنه:

    https://barnamenevis.org/showthread.php?524097

    https://barnamenevis.org/showthread.php?546325

  2. #2
    کاربر دائمی آواتار mazoolagh
    تاریخ عضویت
    اردیبهشت 1384
    سن
    71
    پست
    3,030

    نقل قول: rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

    برای اینکه با rss آشنا بشین میتونین لینک های زیر رو در مرورگر بازکین و فیلدها رو بررسی کنین:

    https://www.isna.ir/rss

    https://www.zoomit.ir/feed/

    https://digiato.com/feed/

    اگر دقت کنید فیلدهای اصلی title و link رو میبینین که اینجا فعلا فقط با این دو سر و کار داریم
    برای آشنایی با فیلدها و فرمت rss بهتره rss validator رو گوگل کنین، ولی با مقایسه همین سه لینک بالا هم دیده میشه که بعضی سایتها ممکنه فیلدهای اضافه تعریف کرده باشن یا اینکه دیتا رو attribute بریزن.

    به همین خاطر برای هر استخراج دقیق و کامل دیتا از یک rss feed بخصوص، باید براش reader اختصاصی بنویسین،
    مگر اینکه مثل اینجا فقط از فیلدهای استاندارد استفاده کرده باشین.

  3. #3
    کاربر دائمی آواتار mazoolagh
    تاریخ عضویت
    اردیبهشت 1384
    سن
    71
    پست
    3,030

    نقل قول: rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

    اول یک تابع برای خوندن دیتا xml مینویسیم،
    در این تابع url میتونه آدرس یک فایل local یا یک آدرس اینترنتی باشه:

    Public Type Response
    xml As MSXML2.DOMDocument60
    ERROR_MESSAGE As String
    End Type

    Public Function Read_xml(File_Url As String) As Response
    On Error GoTo Error_Handler
    Dim REQ As New MSXML2.XMLHTTP60
    REQ.Open "GET", File_Url, False
    REQ.Send
    If REQ.status = 200 Then ' STATUS CODE 200 = OK
    Set Read_xml.xml = REQ.responseXML
    Else
    Set Read_xml.xml = Nothing
    Read_xml.ERROR_MESSAGE = " XMLHttpRequest Error = " & REQ.status & vbCrLf & REQ.statusText
    End If
    Set REQ = Nothing
    Exit Function
    Error_Handler:
    Set Read_xml.xml = Nothing
    Read_xml.ERROR_MESSAGE = "Access Error=" & Err.Number & vbCrLf & Err.description
    Set REQ = Nothing
    End Function

  4. #4
    کاربر دائمی آواتار mazoolagh
    تاریخ عضویت
    اردیبهشت 1384
    سن
    71
    پست
    3,030

    نقل قول: rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

    یک فرم با یک listbox میسازیم و با استفاده از تابع بالا در یک حلقه تمام item ها رو در اون میریزیم:

    Option Compare Database
    Option Explicit
    Const url_isna As String = "https://www.isna.ir/rss"
    Const url_zoomit As String = "https://www.zoomit.ir/feed/"
    Const url_digiato As String = "https://digiato.com/feed/"

    Private Sub Read_RSS(url As String)
    items_list.RowSource = ""
    Dim rr As Response
    rr = Read_xml(url)
    If rr.xml Is Nothing Then
    MsgBox rr.ERROR_MESSAGE
    Exit Sub
    End If
    Dim items As MSXML2.IXMLDOMNodeList
    Dim item As MSXML2.IXMLDOMNode
    Set items = rr.xml.selectNodes("//item")
    For Each item In items
    Me.items_list.AddItem item.selectSingleNode("title").Text & ";" & item.selectSingleNode("link").Text
    Next item
    End Sub

    Private Sub BTN_digiato_Click()
    Read_RSS (url_digiato)
    End Sub

    Private Sub BTN_isna_Click()
    Read_RSS (url_isna)
    End Sub

    Private Sub BTN_zoomit_Click()
    Read_RSS (url_zoomit)
    End Sub

    Private Sub items_list_DblClick(Cancel As Integer)
    DoCmd.OpenForm "Browser", , , , , acDialog, items_list.Column(1)
    End Sub

  5. #5
    کاربر دائمی آواتار mazoolagh
    تاریخ عضویت
    اردیبهشت 1384
    سن
    71
    پست
    3,030

    نقل قول: rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

    نتیجه کار:

    1.PNG

  6. #6
    کاربر دائمی آواتار mazoolagh
    تاریخ عضویت
    اردیبهشت 1384
    سن
    71
    پست
    3,030

    نقل قول: rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

    یک فرم دیگه با یک web browser control میسازیم و با double click روی هر item مقدار link رو بعنوان آدرس براش میفرستیم:

    Private Sub Form_Open(Cancel As Integer)
    Me.wb.ControlSource = "=""" & Me.OpenArgs & """"
    End Sub


  7. #7
    کاربر دائمی آواتار mazoolagh
    تاریخ عضویت
    اردیبهشت 1384
    سن
    71
    پست
    3,030

    نقل قول: rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

    فرم مرورگر:

    2.jpg

  8. #8
    کاربر دائمی آواتار mazoolagh
    تاریخ عضویت
    اردیبهشت 1384
    سن
    71
    پست
    3,030

    نقل قول: rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

    برنامه نمونه:
    فایل های ضمیمه فایل های ضمیمه

  9. #9
    کاربر دائمی
    تاریخ عضویت
    آبان 1397
    محل زندگی
    شیراز
    پست
    315

    نقل قول: rss readr - خواندن فایل های xml و بیرون کشیدن دیتا از آن

    با سلام و احترام
    ممنون از آموزش بسیار عالی جنابعالی
    امیدوارم موفق و پیروز باشید . لطفا در صورت امکان در خصوص کالر پیکر هم راهنمائی بفرمائید .

تاپیک های مشابه

  1. نمایش عکس در RSS Readr
    نوشته شده توسط love20 در بخش ASP.NET Web Forms
    پاسخ: 3
    آخرین پست: پنج شنبه 24 دی 1394, 22:17 عصر
  2. پاسخ: 2
    آخرین پست: یک شنبه 23 تیر 1392, 18:31 عصر
  3. پاسخ: 4
    آخرین پست: سه شنبه 17 آبان 1390, 19:27 عصر
  4. پاسخ: 2
    آخرین پست: چهارشنبه 17 آذر 1389, 20:08 عصر

برچسب های این تاپیک

قوانین ایجاد تاپیک در تالار

  • شما نمی توانید تاپیک جدید ایجاد کنید
  • شما نمی توانید به تاپیک ها پاسخ دهید
  • شما نمی توانید ضمیمه ارسال کنید
  • شما نمی توانید پاسخ هایتان را ویرایش کنید
  •