وب سرویس

[mazoolagh]

Public Type DeliveredFetch_orderPartnerInfo 

   partnerName As String

    partnerPhone As String

    contractPartyName As String

    noMedicalSystem As Long

    licenseName As String

End Type





Public Type DeliveredFetch_subscriptionDeliveredInfo

    numberOfDelivered  As Double

    numberOfRequest As Double

    numberOfPeriod As Double

    description As String

    amount As Double

    patientPayment As Double

    consumption As String

    consumptionInstruction As String

    shape As String

    bulkId As Long

    serviceFullName As String

    serviceShortName As String

    serviceInterfaceName As String

    serviceGenericCode As String

    serviceNationalNumber As String

    serviceDescription As String

    serviceOrderGenericCode As String

    serviceOrderNationalNumber As String

End Type





Public Type DeliveredFetch_Info

    orderedDate As String

    deliveredDate As String

    samadCode As String

    typeId As Long

    totalAmount As Double

    totalPatientPayment As Double

    isVisitSimultaneous As Boolean

    orderPartnerInfo As DeliveredFetch_orderPartnerInfo

    subscriptionDeliveredInfos() As DeliveredFetch_subscriptionDeliveredInfo

    subscriptionDeliveredInfosWithNoReference() As DeliveredFetch_subscriptionDeliveredInfo

End Type





Public Type DeliveredFetch

    resCode As Long

    resMessage As String

    Info As DeliveredFetch_Info

End Type

[mazoolagh]

Public Function FetchPrescriptionDelivered(response As String) As DeliveredFetch

Dim R As Object

Set R = ParseJson(response)





FetchPrescriptionDelivered.resCode = R("resCode")

FetchPrescriptionDelivered.resMessage = R("resMessage")





Dim x, y As Object

Set x = R("info")

Dim Info As DeliveredFetch_Info

Dim i As Integer

With Info

    .orderedDate = x("orderedDate")

    .deliveredDate = x("deliveredDate")

    .samadCode = x("samadCode")

    .typeId = x("typeId")

    .totalAmount = x("totalAmount")

    .totalPatientPayment = x("totalPatientPayment")

    .isVisitSimultaneous = x("isVisitSimultaneous")

    .orderPartnerInfo.partnerName = x("orderPartnerInfo")("partnerName")

    .orderPartnerInfo.partnerPhone = x("orderPartnerInfo")("partnerPhone")

    .orderPartnerInfo.contractPartyName = x("orderPartnerInfo")("contractPartyName")

    .orderPartnerInfo.noMedicalSystem = x("orderPartnerInfo")("noMedicalSystem")

    .orderPartnerInfo.licenseName = x("orderPartnerInfo")("licenseName")

    Dim Infos() As DeliveredFetch_subscriptionDeliveredInfo

    ReDim Infos(1 To x("subscriptionDeliveredInfos").Count)

    For i = 1 To UBound(Infos)

        Set y = x("subscriptionDeliveredInfos")(i)

        With Infos(i)

            .numberOfDelivered = y("numberOfDelivered")

            .numberOfRequest = y("numberOfRequest")

            .numberOfPeriod = y("numberOfPeriod")

            .description = Nz(y("description"), "")

            .amount = y("amount")

            .patientPayment = y("patientPayment")

            .consumption = y("consumption")

            .consumptionInstruction = y("consumptionInstruction")

            .shape = y("shape")

            .bulkId = y("bulkId")

            .serviceFullName = y("serviceFullName")

            .serviceShortName = y("serviceShortName")

            .serviceInterfaceName = y("serviceInterfaceName")

            .serviceGenericCode = y("serviceGenericCode")

            .serviceNationalNumber = y("serviceNationalNumber")

            .serviceDescription = y("serviceDescription")

            .serviceOrderGenericCode = y("serviceOrderGenericCode")

            .serviceOrderNationalNumber = y("serviceOrderNationalNumber")

        End With

    Next

    .subscriptionDeliveredInfos = Infos

End With

FetchPrescriptionDelivered.Info = Info

End Function

[mazoolagh]

همون response رو که فرستادین در یک فایل به نام b.json ریختم و کد رو تست کردم:

Sub test()

Dim df As DeliveredFetch

df = FetchPrescriptionDelivered(ReadTextFile(CurrentPro  ject.Path & "\b.json"))

Debug.Print UBound(df.Info.subscriptionDeliveredInfos)

End Sub

Function ReadTextFile(FilePath As String) As String

Dim T As TextStream

With New FileSystemObject

    Set T = .OpenTextFile(FilePath, ForReading)

    ReadTextFile = T.ReadAll

End With

T.Close

Set T = Nothing

End Function

[mazoolagh]

20.PNG

21.PNG

[mazoolagh]

برنامه نمونه:
فقط یادتون باشه کد subscriptionDeliveredInfos رو برای subscriptionDeliveredInfosWithNoReference هم بنویسین (اگر لازم هست)

[amirzazadeh]

برنامه نمونه:
فقط یادتون باشه کد subscriptionDeliveredInfos رو برای subscriptionDeliveredInfosWithNoReference هم بنویسین (اگر لازم هست)

سلام و درود فراوان
با تشکر بررسی میکنم و نتیجه رو اعلام می کنم.

[mazoolagh]

سلام و درود فراوان
با تشکر بررسی میکنم و نتیجه رو اعلام می کنم.

سلام دوباره و روز شما خوش
اون تاپیک در بخش وب سرویس گویا هیچ کس پاسخی در این مدت نداده و این عجیب هست!
کاش خودتون زمان میگذاشتید براش چون بمراتب کدنویسی و نگهداریش خیلی ساده تر هست.
خودم هم وقت کنم دوباره میرم سروقتش ، فقط بفرمایید که user/pass همون هست که بود؟

[amirzazadeh]

سلام دوباره و روز شما خوش
اون تاپیک در بخش وب سرویس گویا هیچ کس پاسخی در این مدت نداده و این عجیب هست!
کاش خودتون زمان میگذاشتید براش چون بمراتب کدنویسی و نگهداریش خیلی ساده تر هست.
خودم هم وقت کنم دوباره میرم سروقتش ، فقط بفرمایید که user/pass همون هست که بود؟

سلام و وقت به خیر
یوزر و پسورد تست، همون هست که براتون ارسال کردم. در خصوص تاپیک بخش وب سرویس هم انشاالله با کمک شما و سایر دوستان کارو پیش می بریم.
..............................
پیروز و سربلند باشید

[amirzazadeh]

سلام و وقت به خیر جناب mazoolagh
ضمن تشکر و قدردانی ویژه، همونطور که انتظار می رفت کدهای ارسالی شما عالی و کامل نتایج رو برمی گردونند.
..........................
ارادتمند میرزازاده

[atf1379]

سلام
میگم این تاپیک چقدر تخصصی و خصوصی بود ؟

[mazoolagh]

سلام
میگم این تاپیک چقدر تخصصی و خصوصی بود ؟

سلام و روز خوش
تاپیک کاملا تخصصی و حرفه ای هست،
ولی اصلا خصوصی نیست!
برعکس هر کسی که با سیستم های بیمارستانی و پذیرش و ... کار میکنه حتی اگر از اکسس استفاده نکنه میتونه از این تاپیک استفاده کنه.
همینجور کار با وب سرویس (ارسال درخواست، دریافت پاسخ و تفسیر اون و ...) رو که کاملا عمومی و فراگیر هست پوشش میده.

تاپیک زمانی خصوصی هست که یک نفر یک مورد کاملا منحصر بفردی رو مطرح کنه که فقط نیاز خودش هست و کسی که پاسخ میده فقط هدفش پاسخگویی هست (به هر قیمت) بدون آوردن کدها و توضیح در انجمن.
هر تاپیکی که موضوعش شبیه اینها باشه خصوصی محسوب میشه:
- من یک دکمه دارم، یک کت براش بدوزین!
- من به اصول و روش های استاندارد و کار اصولی اعتقادی ندارم ولی خواسته من این است (برای من یک دستشویی اوپن وسط پذیرایی بسازین)!
- من دانش پایه و اولیه نرم افزار و سیستم ها و ... ندارم ولی باید اینجور که من میگم کار کنید (با فرقون و بیل و کلنگ برج بسازین)!

[yeganehaym]

سلام. چطوری میشه API بیمه سلامت رو درخواست داد. ما هر چی از خودشون میپرسیم نمیدونن.

[amirzazadeh]

سلام. چطوری میشه API بیمه سلامت رو درخواست داد. ما هر چی از خودشون میپرسیم نمیدونن.

سلام یه ایمیل به این آدرس بفرستید.asa@ihio.gov.ir

آزمایشگاه سازمان الکترونیک بیمه سلامت ایران
آدرس: شهرک غرب - خیابان فلامک شمالی - ساختمان آریو - ورودی A - سازمان بیمه سلامت ایران - طبقه پنجم - آزمایشگاه و مرکز پایش سازمان الکترونیک بیمه سلامت ایران - تلفن: 02196881606